Project

General

Profile

Statistics
| Branch: | Tag: | Revision:

lustrec / src / typing.ml @ 52cfee34

History | View | Annotate | Download (27.6 KB)

1
(* ----------------------------------------------------------------------------
2
 * SchedMCore - A MultiCore Scheduling Framework
3
 * Copyright (C) 2009-2011, ONERA, Toulouse, FRANCE - LIFL, Lille, FRANCE
4
 *
5
 * This file is part of Prelude
6
 *
7
 * Prelude is free software; you can redistribute it and/or
8
 * modify it under the terms of the GNU Lesser General Public License
9
 * as published by the Free Software Foundation ; either version 2 of
10
 * the License, or (at your option) any later version.
11
 *
12
 * Prelude is distributed in the hope that it will be useful, but
13
 * WITHOUT ANY WARRANTY ; without even the implied warranty of
14
 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
15
 * Lesser General Public License for more details.
16
 *
17
 * You should have received a copy of the GNU Lesser General Public
18
 * License along with this program ; if not, write to the Free Software
19
 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307
20
 * USA
21
 *---------------------------------------------------------------------------- *)
22

    
23
(** Main typing module. Classic inference algorithm with destructive
24
    unification. *)
25

    
26
let debug fmt args = () (* Format.eprintf "%a"  *)
27
(* Though it shares similarities with the clock calculus module, no code
28
    is shared.  Simple environments, very limited identifier scoping, no
29
    identifier redefinition allowed. *)
30

    
31
open Utils
32
(* Yes, opening both modules is dirty as some type names will be
33
   overwritten, yet this makes notations far lighter.*)
34
open LustreSpec
35
open Corelang
36
open Types
37
open Format
38

    
39
let pp_typing_env fmt env =
40
  Env.pp_env print_ty fmt env
41

    
42
(** [occurs tvar ty] returns true if the type variable [tvar] occurs in
43
    type [ty]. False otherwise. *)
44
let rec occurs tvar ty =
45
  let ty = repr ty in
46
  match ty.tdesc with
47
  | Tvar -> ty=tvar
48
  | Tarrow (t1, t2) ->
49
      (occurs tvar t1) || (occurs tvar t2)
50
  | Ttuple tl ->
51
     List.exists (occurs tvar) tl
52
  | Tstruct fl ->
53
     List.exists (fun (f, t) -> occurs tvar t) fl
54
  | Tarray (_, t)
55
  | Tstatic (_, t)
56
  | Tclock t
57
  | Tlink t -> occurs tvar t
58
  | Tenum _ | Tconst _ | Tunivar | Tint | Treal | Tbool | Trat -> false
59

    
60
(** Promote monomorphic type variables to polymorphic type variables. *)
61
(* Generalize by side-effects *)
62
let rec generalize ty =
63
  match ty.tdesc with
64
  | Tvar ->
65
      (* No scopes, always generalize *)
66
      ty.tdesc <- Tunivar
67
  | Tarrow (t1,t2) ->
68
      generalize t1; generalize t2
69
  | Ttuple tl ->
70
     List.iter generalize tl
71
  | Tstruct fl ->
72
     List.iter (fun (f, t) -> generalize t) fl
73
  | Tstatic (d, t)
74
  | Tarray (d, t) -> Dimension.generalize d; generalize t
75
  | Tclock t
76
  | Tlink t ->
77
      generalize t
78
  | Tenum _ | Tconst _ | Tunivar | Tint | Treal | Tbool | Trat -> ()
79

    
80
(** Downgrade polymorphic type variables to monomorphic type variables *)
81
let rec instantiate inst_vars inst_dim_vars ty =
82
  let ty = repr ty in
83
  match ty.tdesc with
84
  | Tenum _ | Tconst _ | Tvar | Tint | Treal | Tbool | Trat -> ty
85
  | Tarrow (t1,t2) ->
86
      {ty with tdesc =
87
       Tarrow ((instantiate inst_vars inst_dim_vars t1), (instantiate inst_vars inst_dim_vars t2))}
88
  | Ttuple tlist ->
89
      {ty with tdesc = Ttuple (List.map (instantiate inst_vars inst_dim_vars) tlist)}
90
  | Tstruct flist ->
91
      {ty with tdesc = Tstruct (List.map (fun (f, t) -> (f, instantiate inst_vars inst_dim_vars t)) flist)}
92
  | Tclock t ->
93
	{ty with tdesc = Tclock (instantiate inst_vars inst_dim_vars t)}
94
  | Tstatic (d, t) ->
95
	{ty with tdesc = Tstatic (Dimension.instantiate inst_dim_vars d, instantiate inst_vars inst_dim_vars t)}
96
  | Tarray (d, t) ->
97
	{ty with tdesc = Tarray (Dimension.instantiate inst_dim_vars d, instantiate inst_vars inst_dim_vars t)}
98
  | Tlink t ->
99
	(* should not happen *)
100
	{ty with tdesc = Tlink (instantiate inst_vars inst_dim_vars t)}
101
  | Tunivar ->
102
      try
103
        List.assoc ty.tid !inst_vars
104
      with Not_found ->
105
        let var = new_var () in
106
	inst_vars := (ty.tid, var)::!inst_vars;
107
	var
108

    
109
(* [type_coretype cty] types the type declaration [cty] *)
110
let rec type_coretype type_dim cty =
111
  match (*get_repr_type*) cty with
112
  | Tydec_any -> new_var ()
113
  | Tydec_int -> Type_predef.type_int
114
  | Tydec_real -> Type_predef.type_real
115
  | Tydec_float -> Type_predef.type_real
116
  | Tydec_bool -> Type_predef.type_bool
117
  | Tydec_clock ty -> Type_predef.type_clock (type_coretype type_dim ty)
118
  | Tydec_const c -> Type_predef.type_const c
119
  | Tydec_enum tl -> Type_predef.type_enum tl
120
  | Tydec_struct fl -> Type_predef.type_struct (List.map (fun (f, ty) -> (f, type_coretype type_dim ty)) fl)
121
  | Tydec_array (d, ty) ->
122
    begin
123
      type_dim d;
124
      Type_predef.type_array d (type_coretype type_dim ty)
125
    end
126

    
127
(* [coretype_type] is the reciprocal of [type_typecore] *)
128
let rec coretype_type ty =
129
 match (repr ty).tdesc with
130
 | Tvar           -> Tydec_any
131
 | Tint           -> Tydec_int
132
 | Treal          -> Tydec_real
133
 | Tbool          -> Tydec_bool
134
 | Tconst c       -> Tydec_const c
135
 | Tclock t       -> Tydec_clock (coretype_type t)
136
 | Tenum tl       -> Tydec_enum tl
137
 | Tstruct fl     -> Tydec_struct (List.map (fun (f, t) -> (f, coretype_type t)) fl)
138
 | Tarray (d, t)  -> Tydec_array (d, coretype_type t)
139
 | Tstatic (_, t) -> coretype_type t
140
 | _         -> assert false
141

    
142
let get_type_definition tname =
143
  try
144
    type_coretype (fun d -> ()) (Hashtbl.find type_table (Tydec_const tname))
145
  with Not_found -> raise (Error (Location.dummy_loc, Unbound_type tname))
146

    
147
(** [unify t1 t2] unifies types [t1] and [t2]. Raises [Unify
148
    (t1,t2)] if the types are not unifiable.*)
149
(* Standard destructive unification *)
150
let rec unify t1 t2 =
151
  let t1 = repr t1 in
152
  let t2 = repr t2 in
153
  if t1=t2 then
154
    ()
155
  else
156
    (* No type abbreviations resolution for now *)
157
    match t1.tdesc,t2.tdesc with
158
      (* This case is not mandory but will keep "older" types *)
159
    | Tvar, Tvar ->
160
        if t1.tid < t2.tid then
161
          t2.tdesc <- Tlink t1
162
        else
163
          t1.tdesc <- Tlink t2
164
    | (Tvar, _) when (not (occurs t1 t2)) ->
165
        t1.tdesc <- Tlink t2
166
    | (_,Tvar) when (not (occurs t2 t1)) ->
167
        t2.tdesc <- Tlink t1
168
    | Tarrow (t1,t2), Tarrow (t1',t2') ->
169
      begin
170
        unify t1 t1';
171
	unify t2 t2'
172
      end
173
    | Ttuple tl, Ttuple tl' when List.length tl = List.length tl' ->
174
      List.iter2 unify tl tl'
175
    | Tstruct fl, Tstruct fl' when List.map fst fl = List.map fst fl' ->
176
      List.iter2 (fun (_, t) (_, t') -> unify t t') fl fl'
177
    | Tclock _, Tstatic _
178
    | Tstatic _, Tclock _ -> raise (Unify (t1, t2))
179
    | Tclock t1', _ -> unify t1' t2
180
    | _, Tclock t2' -> unify t1 t2'
181
    | Tint, Tint | Tbool, Tbool | Trat, Trat
182
    | Tunivar, _ | _, Tunivar -> ()
183
    | (Tconst t, _) ->
184
      let def_t = get_type_definition t in
185
      unify def_t t2
186
    | (_, Tconst t)  ->
187
      let def_t = get_type_definition t in
188
      unify t1 def_t
189
    | Tenum tl, Tenum tl' when tl == tl' -> ()
190
    | Tstruct fl, Tstruct fl' when fl == fl' -> ()
191
    | Tstatic (e1, t1'), Tstatic (e2, t2')
192
    | Tarray (e1, t1'), Tarray (e2, t2') ->
193
      begin
194
	unify t1' t2';
195
	Dimension.eval Basic_library.eval_env (fun c -> None) e1;
196
	Dimension.eval Basic_library.eval_env (fun c -> None) e2;
197
	Dimension.unify e1 e2;
198
      end
199
    | _,_ -> raise (Unify (t1, t2))
200

    
201
(** [semi_unify t1 t2] checks whether type [t1] is an instance of type [t2]. Raises [Unify
202
    (t1,t2)] if the types are not semi-unifiable.*)
203
(* Standard destructive semi-unification *)
204
let rec semi_unify t1 t2 =
205
  let t1 = repr t1 in
206
  let t2 = repr t2 in
207
  if t1=t2 then
208
    ()
209
  else
210
    (* No type abbreviations resolution for now *)
211
    match t1.tdesc,t2.tdesc with
212
      (* This case is not mandory but will keep "older" types *)
213
    | Tvar, Tvar ->
214
        if t1.tid < t2.tid then
215
          t2.tdesc <- Tlink t1
216
        else
217
          t1.tdesc <- Tlink t2
218
    | (Tvar, _) -> raise (Unify (t1, t2))
219
    | (_,Tvar) when (not (occurs t2 t1)) ->
220
        t2.tdesc <- Tlink t1
221
    | Tarrow (t1,t2), Tarrow (t1',t2') ->
222
      begin
223
        semi_unify t1 t1';
224
	semi_unify t2 t2'
225
      end
226
    | Ttuple tl, Ttuple tl' when List.length tl = List.length tl' ->
227
      List.iter2 semi_unify tl tl'
228
    | Tstruct fl, Tstruct fl' when List.map fst fl = List.map fst fl' ->
229
      List.iter2 (fun (_, t) (_, t') -> semi_unify t t') fl fl'
230
    | Tclock _, Tstatic _
231
    | Tstatic _, Tclock _ -> raise (Unify (t1, t2))
232
    | Tclock t1', _ -> semi_unify t1' t2
233
    | _, Tclock t2' -> semi_unify t1 t2'
234
    | Tint, Tint | Tbool, Tbool | Trat, Trat
235
    | Tunivar, _ | _, Tunivar -> ()
236
    | (Tconst t, _) ->
237
      let def_t = get_type_definition t in
238
      semi_unify def_t t2
239
    | (_, Tconst t)  ->
240
      let def_t = get_type_definition t in
241
      semi_unify t1 def_t
242
    | Tenum tl, Tenum tl' when tl == tl' -> ()
243

    
244
    | Tstatic (e1, t1'), Tstatic (e2, t2')
245
    | Tarray (e1, t1'), Tarray (e2, t2') ->
246
      begin
247
	semi_unify t1' t2';
248
	Dimension.eval Basic_library.eval_env (fun c -> Some (Dimension.mkdim_ident Location.dummy_loc c)) e1;
249
	Dimension.eval Basic_library.eval_env (fun c -> Some (Dimension.mkdim_ident Location.dummy_loc c)) e2;
250
	Dimension.semi_unify e1 e2;
251
      end
252
    | _,_ -> raise (Unify (t1, t2))
253

    
254
(* Expected type ty1, got type ty2 *)
255
let try_unify ty1 ty2 loc =
256
  try
257
    unify ty1 ty2
258
  with
259
  | Unify _ ->
260
    raise (Error (loc, Type_clash (ty1,ty2)))
261
  | Dimension.Unify _ ->
262
    raise (Error (loc, Type_clash (ty1,ty2)))
263

    
264
let try_semi_unify ty1 ty2 loc =
265
  try
266
    semi_unify ty1 ty2
267
  with
268
  | Unify _ ->
269
    raise (Error (loc, Type_clash (ty1,ty2)))
270
  | Dimension.Unify _ ->
271
    raise (Error (loc, Type_clash (ty1,ty2)))
272

    
273
(* ty1 is a subtype of ty2 *)
274
let rec sub_unify sub ty1 ty2 =
275
  match (repr ty1).tdesc, (repr ty2).tdesc with
276
  | Ttuple [t1]        , Ttuple [t2]        -> sub_unify sub t1 t2
277
  | Ttuple tl1         , Ttuple tl2         ->
278
    if List.length tl1 <> List.length tl2
279
    then raise (Unify (ty1, ty2))
280
    else List.iter2 (sub_unify sub) tl1 tl2
281
  | Ttuple [t1]        , _                  -> sub_unify sub t1 ty2
282
  | _                  , Ttuple [t2]        -> sub_unify sub ty1 t2
283
  | Tstruct tl1        , Tstruct tl2        ->
284
    if List.map fst tl1 <> List.map fst tl2
285
    then raise (Unify (ty1, ty2))
286
    else List.iter2 (fun (_, t1) (_, t2) -> sub_unify sub t1 t2) tl1 tl2
287
  | Tclock t1          , Tclock t2          -> sub_unify sub t1 t2
288
  | Tclock t1          , _   when sub       -> sub_unify sub t1 ty2
289
  | Tstatic (d1, t1)   , Tstatic (d2, t2)   ->
290
    begin
291
      sub_unify sub t1 t2;
292
      Dimension.eval Basic_library.eval_env (fun c -> None) d1;
293
      Dimension.eval Basic_library.eval_env (fun c -> None) d2;
294
      Dimension.unify d1 d2
295
    end
296
  | Tstatic (r_d, t1)  , _         when sub -> sub_unify sub t1 ty2
297
  | _                                       -> unify ty1 ty2
298

    
299
let try_sub_unify sub ty1 ty2 loc =
300
  try
301
    sub_unify sub ty1 ty2
302
  with
303
  | Unify _ ->
304
    raise (Error (loc, Type_clash (ty1,ty2)))
305
  | Dimension.Unify _ ->
306
    raise (Error (loc, Type_clash (ty1,ty2)))
307

    
308
let rec type_struct_const_field loc (label, c) =
309
  if Hashtbl.mem field_table label
310
  then let tydec = Hashtbl.find field_table label in
311
       let tydec_struct = get_struct_type_fields tydec in
312
       let ty_label = type_coretype (fun d -> ()) (List.assoc label tydec_struct) in
313
       begin
314
	 try_unify ty_label (type_const loc c) loc;
315
	 type_coretype (fun d -> ()) tydec
316
       end
317
  else raise (Error (loc, Unbound_value ("struct field " ^ label)))
318

    
319
and type_const loc c = 
320
  match c with
321
  | Const_int _     -> Type_predef.type_int
322
  | Const_real _    -> Type_predef.type_real
323
  | Const_float _   -> Type_predef.type_real
324
  | Const_array ca  -> let d = Dimension.mkdim_int loc (List.length ca) in
325
		      let ty = new_var () in
326
		      List.iter (fun e -> try_unify ty (type_const loc e) loc) ca;
327
		      Type_predef.type_array d ty
328
  | Const_tag t     ->
329
    if Hashtbl.mem tag_table t
330
    then type_coretype (fun d -> ()) (Hashtbl.find tag_table t)
331
    else raise (Error (loc, Unbound_value ("enum tag " ^ t)))
332
  | Const_struct fl ->
333
    let ty_struct = new_var () in
334
    begin
335
      let used =
336
	List.fold_left
337
	  (fun acc (l, c) ->
338
	    if List.mem l acc
339
	    then raise (Error (loc, Already_bound ("struct field " ^ l)))
340
	    else try_unify ty_struct (type_struct_const_field loc (l, c)) loc; l::acc)
341
	  [] fl in
342
      try
343
	let total = List.map fst (get_struct_type_fields (coretype_type ty_struct)) in
344
(*	List.iter (fun l -> Format.eprintf "total: %s@." l) total;
345
	List.iter (fun l -> Format.eprintf "used: %s@." l) used; *)
346
	let undef = List.find (fun l -> not (List.mem l used)) total
347
	in raise (Error (loc, Unbound_value ("struct field " ^ undef)))
348
      with Not_found -> 
349
	ty_struct
350
    end
351

    
352
(* The following typing functions take as parameter an environment [env]
353
   and whether the element being typed is expected to be constant [const]. 
354
   [env] is a pair composed of:
355
  - a map from ident to type, associating to each ident, i.e. 
356
    variables, constants and (imported) nodes, its type including whether
357
    it is constant or not. This latter information helps in checking constant 
358
    propagation policy in Lustre.
359
  - a vdecl list, in order to modify types of declared variables that are
360
    later discovered to be clocks during the typing process.
361
*)
362
let check_constant loc const_expected const_real =
363
  if const_expected && not const_real
364
  then raise (Error (loc, Not_a_constant))
365

    
366
let rec type_standard_args env in_main const expr_list =
367
  let ty_list = List.map (fun e -> dynamic_type (type_expr env in_main const e)) expr_list in
368
  let ty_res = new_var () in
369
  List.iter2 (fun e ty -> try_unify ty_res ty e.expr_loc) expr_list ty_list;
370
  ty_res
371

    
372
(* emulates a subtyping relation between types t and (d : t),
373
   used during node applications and assignments *)
374
and type_subtyping_arg env in_main ?(sub=true) const real_arg formal_type =
375
  let loc = real_arg.expr_loc in
376
  let const = const || (Types.get_static_value formal_type <> None) in
377
  let real_type = type_expr env in_main const real_arg in
378
  let real_type =
379
    if const
380
    then let d =
381
	   if is_dimension_type real_type
382
	   then dimension_of_expr real_arg
383
	   else Dimension.mkdim_var () in
384
	 let eval_const id = Types.get_static_value (Env.lookup_value (fst env) id) in
385
	 Dimension.eval Basic_library.eval_env eval_const d;
386
	 let real_static_type = Type_predef.type_static d (Types.dynamic_type real_type) in
387
	 (match Types.get_static_value real_type with
388
	 | None    -> ()
389
	 | Some d' -> try_unify real_type real_static_type loc);
390
	 real_static_type
391
    else real_type in
392
  (*Format.eprintf "subtyping const %B real %a:%a vs formal %a@." const Printers.pp_expr real_arg Types.print_ty real_type Types.print_ty formal_type;*)
393
  try_sub_unify sub real_type formal_type loc
394

    
395
and type_ident env in_main loc const id =
396
  type_expr env in_main const (expr_of_ident id loc)
397

    
398
(* typing an application implies:
399
   - checking that const formal parameters match real const (maybe symbolic) arguments
400
   - checking type adequation between formal and real arguments
401
*)
402
and type_appl env in_main loc const f args =
403
  let tfun = type_ident env in_main loc const f in
404
  let tins, touts = split_arrow tfun in
405
  let tins = type_list_of_type tins in
406
  let args = expr_list_of_expr args in
407
  List.iter2 (type_subtyping_arg env in_main const) args tins;
408
  touts
409

    
410
(** [type_expr env in_main expr] types expression [expr] in environment
411
    [env], expecting it to be [const] or not. *)
412
and type_expr env in_main const expr =
413
  let res = 
414
  match expr.expr_desc with
415
  | Expr_const c ->
416
    let ty = type_const expr.expr_loc c in
417
    let ty = Type_predef.type_static (Dimension.mkdim_var ()) ty in
418
    expr.expr_type <- ty;
419
    ty
420
  | Expr_ident v ->
421
    let tyv =
422
      try
423
        Env.lookup_value (fst env) v
424
      with Not_found ->
425
	Format.eprintf "Failure in typing expr %a@." Printers.pp_expr expr;
426
        raise (Error (expr.expr_loc, Unbound_value ("identifier " ^ v)))
427
    in
428
    let ty = instantiate (ref []) (ref []) tyv in
429
    let ty' =
430
      if const
431
      then Type_predef.type_static (Dimension.mkdim_var ()) (new_var ())
432
      else new_var () in
433
    try_unify ty ty' expr.expr_loc;
434
    expr.expr_type <- ty;
435
    ty 
436
  | Expr_array elist ->
437
    let ty_elt = type_standard_args env in_main const elist in
438
    let d = Dimension.mkdim_int expr.expr_loc (List.length elist) in
439
    let ty = Type_predef.type_array d ty_elt in
440
    expr.expr_type <- ty;
441
    ty
442
  | Expr_access (e1, d) ->
443
    type_subtyping_arg env in_main true (expr_of_dimension d) Type_predef.type_int;
444
    let ty_elt = new_var () in
445
    let d = Dimension.mkdim_var () in
446
    type_subtyping_arg env in_main const e1 (Type_predef.type_array d ty_elt);
447
    expr.expr_type <- ty_elt;
448
    ty_elt
449
  | Expr_power (e1, d) ->
450
    let eval_const id = Types.get_static_value (Env.lookup_value (fst env) id) in
451
    type_subtyping_arg env in_main true (expr_of_dimension d) Type_predef.type_int;
452
    Dimension.eval Basic_library.eval_env eval_const d;
453
    let ty_elt = type_standard_args env in_main const [e1] in
454
    let ty = Type_predef.type_array d ty_elt in
455
    expr.expr_type <- ty;
456
    ty
457
  | Expr_tuple elist ->
458
    let ty = new_ty (Ttuple (List.map (type_expr env in_main const) elist)) in
459
    expr.expr_type <- ty;
460
    ty
461
  | Expr_ite (c, t, e) ->
462
    type_subtyping_arg env in_main const c Type_predef.type_bool;
463
    let ty = type_standard_args env in_main const [t; e] in
464
    expr.expr_type <- ty;
465
    ty
466
  | Expr_appl (id, args, r) ->
467
    (* application of non internal function is not legal in a constant
468
       expression *)
469
    (match r with
470
    | None        -> ()
471
    | Some (x, l) -> 
472
      check_constant expr.expr_loc const false;
473
      let expr_x = expr_of_ident x expr.expr_loc in	
474
      let typ_l = 
475
	Type_predef.type_clock 
476
	  (type_const expr.expr_loc (Const_tag l)) in
477
      type_subtyping_arg env in_main ~sub:false const expr_x typ_l);
478
    let touts = type_appl env in_main expr.expr_loc const id args in
479
    expr.expr_type <- touts;
480
    touts
481
  | Expr_fby (e1,e2)
482
  | Expr_arrow (e1,e2) ->
483
    (* fby/arrow is not legal in a constant expression *)
484
    check_constant expr.expr_loc const false;
485
    let ty = type_standard_args env in_main const [e1; e2] in
486
    expr.expr_type <- ty;
487
    ty
488
  | Expr_pre e ->
489
    (* pre is not legal in a constant expression *)
490
    check_constant expr.expr_loc const false;
491
    let ty = type_standard_args env in_main const [e] in
492
    expr.expr_type <- ty;
493
    ty
494
  | Expr_when (e1,c,l) ->
495
    (* when is not legal in a constant expression *)
496
    check_constant expr.expr_loc const false;
497
    let typ_l = Type_predef.type_clock (type_const expr.expr_loc (Const_tag l)) in
498
    let expr_c = expr_of_ident c expr.expr_loc in
499
    type_subtyping_arg env in_main ~sub:false const expr_c typ_l;
500
    update_clock env in_main c expr.expr_loc typ_l;
501
    let ty = type_standard_args env in_main const [e1] in
502
    expr.expr_type <- ty;
503
    ty
504
  | Expr_merge (c,hl) ->
505
    (* merge is not legal in a constant expression *)
506
    check_constant expr.expr_loc const false;
507
    let typ_in, typ_out = type_branches env in_main expr.expr_loc const hl in
508
    let expr_c = expr_of_ident c expr.expr_loc in
509
    let typ_l = Type_predef.type_clock typ_in in
510
    type_subtyping_arg env in_main ~sub:false const expr_c typ_l;
511
    update_clock env in_main c expr.expr_loc typ_l;
512
    expr.expr_type <- typ_out;
513
    typ_out
514
  | Expr_uclock (e,k) | Expr_dclock (e,k) ->
515
      let ty = type_expr env in_main const e in
516
      expr.expr_type <- ty;
517
      ty
518
  | Expr_phclock (e,q) ->
519
      let ty = type_expr env in_main const e in
520
      expr.expr_type <- ty;
521
      ty
522
  in (*Format.eprintf "typing %B %a at %a = %a@." const Printers.pp_expr expr Location.pp_loc expr.expr_loc Types.print_ty res;*) res
523

    
524
and type_branches env in_main loc const hl =
525
  let typ_in = new_var () in
526
  let typ_out = new_var () in
527
  try
528
    let used_labels =
529
      List.fold_left (fun accu (t, h) ->
530
	unify typ_in (type_const loc (Const_tag t));
531
	type_subtyping_arg env in_main const h typ_out;
532
	if List.mem t accu
533
	then raise (Error (loc, Already_bound t))
534
	else t :: accu) [] hl in
535
    let type_labels = get_enum_type_tags (coretype_type typ_in) in
536
    if List.sort compare used_labels <> List.sort compare type_labels
537
    then let unbound_tag = List.find (fun t -> not (List.mem t used_labels)) type_labels in
538
	 raise (Error (loc, Unbound_value ("branching tag " ^ unbound_tag)))
539
    else (typ_in, typ_out)
540
  with Unify (t1, t2) ->
541
    raise (Error (loc, Type_clash (t1,t2)))
542

    
543
and update_clock env in_main id loc typ =
544
 (*Log.report ~level:1 (fun fmt -> Format.fprintf fmt "update_clock %s with %a@ " id print_ty typ);*)
545
 try
546
   let vdecl = List.find (fun v -> v.var_id = id) (snd env)
547
   in vdecl.var_type <- typ
548
 with
549
   Not_found ->
550
   raise (Error (loc, Unbound_value ("clock " ^ id)))
551

    
552
(** [type_eq env eq] types equation [eq] in environment [env] *)
553
let type_eq env in_main undefined_vars eq =
554
  (* Check undefined variables, type lhs *)
555
  let expr_lhs = expr_of_expr_list eq.eq_loc (List.map (fun v -> expr_of_ident v eq.eq_loc) eq.eq_lhs) in
556
  let ty_lhs = type_expr env in_main false expr_lhs in
557
  (* Check multiple variable definitions *)
558
  let define_var id uvars =
559
    try
560
      ignore(IMap.find id uvars);
561
      IMap.remove id uvars
562
    with Not_found ->
563
      raise (Error (eq.eq_loc, Already_defined id))
564
  in
565
  let undefined_vars =
566
    List.fold_left (fun uvars v -> define_var v uvars) undefined_vars eq.eq_lhs in
567
  (* Type rhs wrt to lhs type with subtyping, i.e. a constant rhs value may be assigned
568
     to a (always non-constant) lhs variable *)
569
  type_subtyping_arg env in_main false eq.eq_rhs ty_lhs;
570
  undefined_vars
571

    
572

    
573
(* [type_coreclock env ck id loc] types the type clock declaration [ck]
574
   in environment [env] *)
575
let type_coreclock env ck id loc =
576
  match ck.ck_dec_desc with
577
  | Ckdec_any | Ckdec_pclock (_,_) -> ()
578
  | Ckdec_bool cl ->
579
      let dummy_id_expr = expr_of_ident id loc in
580
      let when_expr =
581
        List.fold_left
582
          (fun expr (x, l) ->
583
                {expr_tag = new_tag ();
584
                 expr_desc= Expr_when (expr,x,l);
585
                 expr_type = new_var ();
586
                 expr_clock = Clocks.new_var true;
587
                 expr_delay = Delay.new_var ();
588
                 expr_loc=loc;
589
		 expr_annot = None})
590
          dummy_id_expr cl
591
      in
592
      ignore (type_expr env false false when_expr)
593

    
594
let rec check_type_declaration loc cty =
595
 match cty with
596
 | Tydec_clock ty
597
 | Tydec_array (_, ty) -> check_type_declaration loc ty
598
 | Tydec_const tname   ->
599
   if not (Hashtbl.mem type_table cty)
600
   then raise (Error (loc, Unbound_type tname));
601
 | _                   -> ()
602

    
603
let type_var_decl vd_env env vdecl =
604
  check_type_declaration vdecl.var_loc vdecl.var_dec_type.ty_dec_desc;
605
  let eval_const id = Types.get_static_value (Env.lookup_value env id) in
606
  let type_dim d =
607
    begin
608
      type_subtyping_arg (env, vd_env) false true (expr_of_dimension d) Type_predef.type_int;
609
      Dimension.eval Basic_library.eval_env eval_const d;
610
    end in
611
  let ty = type_coretype type_dim vdecl.var_dec_type.ty_dec_desc in
612
  let ty_status =
613
    if vdecl.var_dec_const
614
    then Type_predef.type_static (Dimension.mkdim_var ()) ty
615
    else ty in
616
  let new_env = Env.add_value env vdecl.var_id ty_status in
617
  type_coreclock (new_env,vd_env) vdecl.var_dec_clock vdecl.var_id vdecl.var_loc;
618
  vdecl.var_type <- ty_status;
619
  new_env
620

    
621
let type_var_decl_list vd_env env l =
622
  List.fold_left (type_var_decl vd_env) env l
623

    
624
let type_of_vlist vars =
625
  let tyl = List.map (fun v -> v.var_type) vars in
626
  type_of_type_list tyl
627

    
628
let add_vdecl vd_env vdecl =
629
 if List.exists (fun v -> v.var_id = vdecl.var_id) vd_env
630
 then raise (Error (vdecl.var_loc, Already_bound vdecl.var_id))
631
 else vdecl::vd_env
632

    
633
let check_vd_env vd_env =
634
  ignore (List.fold_left add_vdecl [] vd_env)
635

    
636
(** [type_node env nd loc] types node [nd] in environment env. The
637
    location is used for error reports. *)
638
let type_node env nd loc =
639
  let is_main = nd.node_id = !Options.main_node in
640
  let vd_env_ol = nd.node_outputs@nd.node_locals in
641
  let vd_env =  nd.node_inputs@vd_env_ol in
642
  check_vd_env vd_env;
643
  let init_env = env in
644
  let delta_env = type_var_decl_list vd_env init_env nd.node_inputs in
645
  let delta_env = type_var_decl_list vd_env delta_env nd.node_outputs in
646
  let delta_env = type_var_decl_list vd_env delta_env nd.node_locals in
647
  let new_env = Env.overwrite env delta_env in
648
  let undefined_vars_init =
649
    List.fold_left
650
      (fun uvs v -> IMap.add v.var_id () uvs)
651
      IMap.empty vd_env_ol in
652
  let undefined_vars =
653
    List.fold_left (type_eq (new_env, vd_env) is_main) undefined_vars_init nd.node_eqs
654
  in
655
  (* check that table is empty *)
656
  if (not (IMap.is_empty undefined_vars)) then
657
    raise (Error (loc, Undefined_var undefined_vars));
658
  let ty_ins = type_of_vlist nd.node_inputs in
659
  let ty_outs = type_of_vlist nd.node_outputs in
660
  let ty_node = new_ty (Tarrow (ty_ins,ty_outs)) in
661
  generalize ty_node;
662
  (* TODO ? Check that no node in the hierarchy remains polymorphic ? *)
663
  nd.node_type <- ty_node;
664
  Env.add_value env nd.node_id ty_node
665

    
666
let type_imported_node env nd loc =
667
  let new_env = type_var_decl_list nd.nodei_inputs env nd.nodei_inputs in
668
  let vd_env = nd.nodei_inputs@nd.nodei_outputs in
669
  check_vd_env vd_env;
670
  ignore(type_var_decl_list vd_env new_env nd.nodei_outputs);
671
  let ty_ins = type_of_vlist nd.nodei_inputs in
672
  let ty_outs = type_of_vlist nd.nodei_outputs in
673
  let ty_node = new_ty (Tarrow (ty_ins,ty_outs)) in
674
  generalize ty_node;
675
(*
676
  if (is_polymorphic ty_node) then
677
    raise (Error (loc, Poly_imported_node nd.nodei_id));
678
*)
679
  let new_env = Env.add_value env nd.nodei_id ty_node in
680
  nd.nodei_type <- ty_node;
681
  new_env
682

    
683
let type_top_consts env clist =
684
  List.fold_left (fun env cdecl ->
685
    let ty = type_const cdecl.const_loc cdecl.const_value in
686
    let d =
687
      if is_dimension_type ty
688
      then dimension_of_const cdecl.const_loc cdecl.const_value
689
      else Dimension.mkdim_var () in
690
    let ty = Type_predef.type_static d ty in
691
    let new_env = Env.add_value env cdecl.const_id ty in
692
    cdecl.const_type <- ty;
693
    new_env) env clist
694

    
695
let type_top_decl env decl =
696
  match decl.top_decl_desc with
697
  | Node nd -> (
698
      try
699
	type_node env nd decl.top_decl_loc
700
      with Error (loc, err) as exc -> (
701
	if !Options.global_inline then
702
	  Format.eprintf "Type error: failing node@.%a@.@?"
703
	    Printers.pp_node nd
704
	;
705
	raise exc)
706
  )
707
  | ImportedNode nd ->
708
      type_imported_node env nd decl.top_decl_loc
709
  | Consts clist ->
710
      type_top_consts env clist
711
  | Open _  -> env
712

    
713
let type_prog env decls =
714
try
715
  List.fold_left type_top_decl env decls
716
with Failure _ as exc -> raise exc
717

    
718
(* Once the Lustre program is fully typed,
719
   we must get back to the original description of dimensions,
720
   with constant parameters, instead of unifiable internal variables. *)
721

    
722
(* The following functions aims at 'unevaluating' dimension expressions occuring in array types,
723
   i.e. replacing unifiable second_order variables with the original static parameters.
724
   Once restored in this formulation, dimensions may be meaningfully printed.
725
*)
726
let uneval_vdecl_generics vdecl =
727
 if vdecl.var_dec_const
728
 then
729
   match get_static_value vdecl.var_type with
730
   | None   -> (Format.eprintf "internal error: %a@." Types.print_ty vdecl.var_type; assert false)
731
   | Some d -> Dimension.uneval vdecl.var_id d
732

    
733
let uneval_node_generics vdecls =
734
  List.iter uneval_vdecl_generics vdecls
735

    
736
let uneval_top_generics decl =
737
  match decl.top_decl_desc with
738
  | Node nd ->
739
      uneval_node_generics (nd.node_inputs @ nd.node_outputs)
740
  | ImportedNode nd ->
741
      uneval_node_generics (nd.nodei_inputs @ nd.nodei_outputs)
742
  | Consts clist -> ()
743
  | Open _  -> ()
744

    
745
let uneval_prog_generics prog =
746
 List.iter uneval_top_generics prog
747

    
748
let check_env_compat header declared computed = 
749
  uneval_prog_generics header;
750
  Env.iter declared (fun k decl_type_k -> 
751
    let computed_t = instantiate (ref []) (ref []) (Env.lookup_value computed k) in
752
    (*Types.print_ty Format.std_formatter decl_type_k;
753
    Types.print_ty Format.std_formatter computed_t;*)
754
    try_semi_unify decl_type_k computed_t Location.dummy_loc
755
  ) 
756

    
757
(* Local Variables: *)
758
(* compile-command:"make -C .." *)
759
(* End: *)