CristalCaveGem » LustreC

(* ----------------------------------------------------------------------------

 * SchedMCore - A MultiCore Scheduling Framework

 * Copyright (C) 2009-2013, ONERA, Toulouse, FRANCE - LIFL, Lille, FRANCE

 * Copyright (C) 2012-2013, INPT, Toulouse, FRANCE

 *

 * This file is part of Prelude

 *

 * Prelude is free software; you can redistribute it and/or

 * modify it under the terms of the GNU Lesser General Public License

 * as published by the Free Software Foundation ; either version 2 of

 * the License, or (at your option) any later version.

 *

 * Prelude is distributed in the hope that it will be useful, but

 * WITHOUT ANY WARRANTY ; without even the implied warranty of

 * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU

 * Lesser General Public License for more details.

 *

 * You should have received a copy of the GNU Lesser General Public

 * License along with this program ; if not, write to the Free Software

 * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA 02111-1307

 * USA

 *---------------------------------------------------------------------------- *)

(* This module is used for the lustre to C compiler *)

open Corelang

open Clocks

open Causality

exception NormalizationError

module OrdVarDecl:Map.OrderedType with type t=var_decl =

  struct type t = var_decl;; let compare = compare end

module ISet = Set.Make(OrdVarDecl)

type value_t = 

  | Cst of constant

  | LocalVar of var_decl

  | StateVar of var_decl

  | Fun of ident * value_t list 

  | Array of value_t list

  | Access of value_t * value_t

  | Power of value_t * value_t

type instr_t =

  | MLocalAssign of var_decl * value_t

  | MStateAssign of var_decl * value_t

  | MReset of ident

  | MStep of var_decl list * ident * value_t list

  | MBranch of value_t * (label * instr_t list) list

let rec pp_val fmt v =

  match v with

    | Cst c         -> Printers.pp_const fmt c 

    | LocalVar v    -> Format.pp_print_string fmt v.var_id

    | StateVar v    -> Format.pp_print_string fmt v.var_id

    | Array vl      -> Format.fprintf fmt "[%a]" (Utils.fprintf_list ~sep:", " pp_val)  vl

    | Access (t, i) -> Format.fprintf fmt "%a[%a]" pp_val t pp_val i

    | Power (v, n)  -> Format.fprintf fmt "(%a^%a)" pp_val v pp_val n

    | Fun (n, vl)   -> Format.fprintf fmt "%s (%a)" n (Utils.fprintf_list ~sep:", " pp_val)  vl

let rec pp_instr fmt i =

  match i with 

    | MLocalAssign (i,v) -> Format.fprintf fmt "%s<-l- %a" i.var_id pp_val v

    | MStateAssign (i,v) -> Format.fprintf fmt "%s<-s- %a" i.var_id pp_val v

    | MReset i           -> Format.fprintf fmt "reset %s" i

    | MStep (il, i, vl)  ->

      Format.fprintf fmt "%a = %s (%a)"

	(Utils.fprintf_list ~sep:", " (fun fmt v -> Format.pp_print_string fmt v.var_id)) il

	i      

	(Utils.fprintf_list ~sep:", " pp_val) vl

    | MBranch (g,hl)     ->

      Format.fprintf fmt "@[<v 2>case(%a) {@,%a@,}@]"

	pp_val g

	(Utils.fprintf_list ~sep:"@," pp_branch) hl

and pp_branch fmt (t, h) =

  Format.fprintf fmt "@[<v 2>%s:@,%a@]" t (Utils.fprintf_list ~sep:"@," pp_instr) h

type step_t = {

  step_checks: (Location.t * value_t) list;

  step_inputs: var_decl list;

  step_outputs: var_decl list;

  step_locals: var_decl list;

  step_instrs: instr_t list;

}

type static_call = top_decl * (Dimension.dim_expr list)

type eexpr_minimachine_t = {

  muid: tag;

  mquantifiers: (quantifier_type * var_decl list) list;

  mmmemory: var_decl list;

  mmcalls: (ident * static_call) list;     (* map from stateful/stateless instance to node, 

					      no internals *)

  mminstances: (ident * static_call) list; (* sub-map of mcalls, from stateful instance to node *)

  mminit: instr_t list;

  mmstep_logic: step_t;  

  mmstep_effects: step_t;  

  (* mmlogic: step_t;   *)

}

type spec_machine_t = {

  m_requires: eexpr_minimachine_t list;

  m_ensures: eexpr_minimachine_t list;

  m_behaviors: (string * eexpr_minimachine_t list * eexpr_minimachine_t list) list;

}

type machine_t = {

  mname: node_desc;

  mmemory: var_decl list;

  mcalls: (ident * static_call) list; (* map from stateful/stateless instance to node, no internals *)

  minstances: (ident * static_call) list; (* sub-map of mcalls, from stateful instance to node *)

  minit: instr_t list;

  mstatic: var_decl list; (* static inputs only *)

  mstep: step_t;

  mspec: spec_machine_t option;

  mannot: (string list * eexpr_minimachine_t) list;

}

let get_val_type v =

match v with 

| Cst c -> (Typing.type_const Location.dummy_loc c).Types.tdesc

| LocalVar v 

| StateVar v-> (Types.repr v.var_type).Types.tdesc

| Fun _

| Array _

| Access _

| Power _ -> raise (Not_found) (* Not a variable *)

let pp_step fmt s =

  Format.fprintf fmt "@[<v>inputs : %a@ outputs: %a@ locals : %a@ checks : %a@ instrs : @[%a@]@]@ "

    (Utils.fprintf_list ~sep:", " Printers.pp_var) s.step_inputs

    (Utils.fprintf_list ~sep:", " Printers.pp_var) s.step_outputs

    (Utils.fprintf_list ~sep:", " Printers.pp_var) s.step_locals

    (Utils.fprintf_list ~sep:", " (fun fmt (_, c) -> pp_val fmt c)) s.step_checks

    (Utils.fprintf_list ~sep:"@ " pp_instr) s.step_instrs

let pp_static_call fmt (node, args) =

 Format.fprintf fmt "%s<%a>"

   (node_name node)

   (Utils.fprintf_list ~sep:", " Dimension.pp_dimension) args

let pp_eexpr fmt ee =

  Format.fprintf fmt 

    "%a%t @[<v 2>mem      : %a@;instances: %a@;init     : %a@;logic step     :@;  @[<v 2>%a@]@;effects step     :@;  @[<v 2>%a@]@;@]@;"

    (Utils.fprintf_list ~sep:"; " Printers.pp_quantifiers) ee.mquantifiers

    (fun fmt -> match ee.mquantifiers with [] -> () | _ -> Format.fprintf fmt ";")

    (Utils.fprintf_list ~sep:", " Printers.pp_var) ee.mmmemory

    (Utils.fprintf_list ~sep:", " (fun fmt (o1, o2) -> Format.fprintf fmt "(%s, %a)" o1 pp_static_call o2)) ee.mminstances

    (Utils.fprintf_list ~sep:"@ " pp_instr) ee.mminit

    pp_step ee.mmstep_logic

    pp_step ee.mmstep_effects

let pp_spec fmt spec =

  Format.fprintf fmt "@[<hov 2>(*@@ ";

  Utils.fprintf_list ~sep:"@;@@ " (fun fmt r -> Format.fprintf fmt "requires %a;" pp_eexpr r) fmt spec.m_requires;

  Utils.fprintf_list ~sep:"@;@@ " (fun fmt r -> Format.fprintf fmt "ensures %a; " pp_eexpr r) fmt spec.m_ensures;

  Utils.fprintf_list ~sep:"@;" (fun fmt (name, assumes, ensures) -> 

    Format.fprintf fmt "behavior %s:@[@ %a@ %a@]" 

      name

      (Utils.fprintf_list ~sep:"@ " (fun fmt r -> Format.fprintf fmt "assumes %a;" pp_eexpr r)) assumes

      (Utils.fprintf_list ~sep:"@ " (fun fmt r -> Format.fprintf fmt "ensures %a;" pp_eexpr r)) ensures

  ) fmt spec.m_behaviors;

  Format.fprintf fmt "@]*)";

  ()

let pp_machine fmt m =

  Format.fprintf fmt 

    "@[<v 2>machine %s@;mem      : %a@;instances: %a@;init     : %a@;step     :@;  @[<v 2>%a@]@;spec: %a@;@]@ "

    m.mname.node_id

    (Utils.fprintf_list ~sep:", " Printers.pp_var) m.mmemory

    (Utils.fprintf_list ~sep:", " (fun fmt (o1, o2) -> Format.fprintf fmt "(%s, %a)" o1 pp_static_call o2)) m.minstances

    (Utils.fprintf_list ~sep:"@ " pp_instr) m.minit

    pp_step m.mstep

    (fun fmt s -> match s with None -> () | Some s -> pp_spec fmt s) m.mspec

let is_output m id =

  List.exists (fun o -> o.var_id = id.var_id) m.mstep.step_outputs

let conditional c t e =

  MBranch(c, [ (tag_true, t); (tag_false, e) ])

let dummy_var_decl name typ =

  {

    var_id = name;

    var_dec_type = dummy_type_dec;

    var_dec_clock = dummy_clock_dec;

    var_dec_const = false;

    var_type =  typ;

    var_clock = Clocks.new_ck (Clocks.Cvar Clocks.CSet_all) true;

    var_loc = Location.dummy_loc

  }

let arrow_id = "_arrow"

let arrow_typ = Types.new_ty Types.Tunivar

let arrow_desc =

  {

    node_id = arrow_id;

    node_type = Type_predef.type_bin_poly_op;

    node_clock = Clock_predef.ck_bin_univ;

    node_inputs= [dummy_var_decl "_in1" arrow_typ; dummy_var_decl "_in2" arrow_typ];

    node_outputs= [dummy_var_decl "_out" arrow_typ];

    node_locals= [];

    node_gencalls = [];

    node_checks = [];

    node_asserts = [];

    node_eqs= [];

    node_spec = None;

    node_annot = [];  }

let arrow_top_decl =

  {

    top_decl_desc = Node arrow_desc;

    top_decl_loc = Location.dummy_loc

  }

let arrow_machine =

  let state = "_first" in

  let var_state = dummy_var_decl state (Types.new_ty Types.Tbool) in

  let var_input1 = List.nth arrow_desc.node_inputs 0 in

  let var_input2 = List.nth arrow_desc.node_inputs 1 in

  let var_output = List.nth arrow_desc.node_outputs 0 in

  {

    mname = arrow_desc;

    mmemory = [var_state];

    mcalls = [];

    minstances = [];

    minit = [MStateAssign(var_state, Cst (const_of_bool true))];

    mstatic = [];

    mstep = {

      step_inputs = arrow_desc.node_inputs;

      step_outputs = arrow_desc.node_outputs;

      step_locals = [];

      step_checks = [];

      step_instrs = [conditional (StateVar var_state)

			         [MStateAssign(var_state, Cst (const_of_bool false));

                                  MLocalAssign(var_output, LocalVar var_input1)]

                                 [MLocalAssign(var_output, LocalVar var_input2)] ]

    };

    mspec = None;

    mannot = [];

  }

let is_stateless_node node =

  (node_name node <> arrow_id) &&

    match node.top_decl_desc with

    | Node id -> false (* TODO: add a check after the machines are produced. Start from the main node and do a DFS to compute the stateless/statefull property of nodes. Stateless nodes should not be reset *)

    | ImportedNode id -> id.nodei_stateless

    | ImportedFun _ -> true

    | _       -> assert false

let new_instance =

  let cpt = ref (-1) in

  fun caller callee tag ->

    begin

      let o =

	if is_stateless_node callee then

	  node_name callee

	else

	  Printf.sprintf "ni_%d" (incr cpt; !cpt) in

      let o =

	if !Options.ansi && is_generic_node callee

	then Printf.sprintf "%s_inst_%d" o (Utils.position (fun e -> e.expr_tag = tag) caller.node_gencalls)

	else o in

      o

    end

let const_of_carrier cr =

 match (carrier_repr cr).carrier_desc with

 | Carry_const id -> id

 | Carry_name -> assert false

 | Carry_var -> assert false

 | Carry_link _ -> assert false (* TODO check this Xavier *)

(* translate_<foo> : node -> context -> <foo> -> machine code/expression *)

(* the context contains  m : state aka memory variables  *)

(*                      si : initialization instructions *)

(*                       j : node aka machine instances  *)

(*                       d : local variables             *)

(*                       s : step instructions           *)

let translate_ident vars (m, si, j, d, s) id =

  try (* id is a node var *)

    (* Format.eprintf "translate ident: %s@.@?" id; *)

    let var_id = try List.find (fun v -> v.var_id=  id) vars with Not_found -> assert false in

    if ISet.exists (fun v -> v.var_id = id) m

    then StateVar var_id

    else LocalVar var_id

  with Not_found -> (* id is a constant *)

    LocalVar (Corelang.var_decl_of_const (Hashtbl.find Corelang.consts_table id))

let rec control_on_clock vars ((m, si, j, d, s) as args) ck inst =

 match ck.cdesc with

 | Con    (ck1, cr, l) ->

   let id  = const_of_carrier cr in

   control_on_clock vars args ck1 (MBranch (translate_ident vars args id,

					    [l, [inst]] ))

 | _                   -> inst

let rec join_branches hl1 hl2 =

 match hl1, hl2 with

 | []          , _            -> hl2

 | _           , []           -> hl1

 | (t1, h1)::q1, (t2, h2)::q2 ->

   if t1 < t2 then (t1, h1) :: join_branches q1 hl2 else

   if t1 > t2 then (t2, h2) :: join_branches hl1 q2

   else (t1, List.fold_right join_guards h1 h2) :: join_branches q1 q2

and join_guards inst1 insts2 =

 match inst1, insts2 with

 | _                   , []                               ->

   [inst1]

 | MBranch (x1, hl1), MBranch (x2, hl2) :: q when x1 = x2 ->

   MBranch (x1, join_branches (sort_handlers hl1) (sort_handlers hl2))

   :: q

 | _ -> inst1 :: insts2

let join_guards_list insts =

 List.fold_right join_guards insts []

let find_eq x eqs =

  let rec aux accu eqs =

      match eqs with

	| [] ->

	  begin

	    Format.eprintf "Looking for variable %a in the following equations@.%a@.@?"

	      Format.pp_print_string x

	      Printers.pp_node_eqs eqs;

	    assert false

	  end

	| hd::tl -> 

	  if List.mem x hd.eq_lhs then hd, accu@tl else aux (hd::accu) tl

    in

    aux [] eqs

let rec translate_expr vars ((m, si, j, d, s) as args) expr =

 match expr.expr_desc with

 | Expr_const v                     -> Cst v

 | Expr_ident x                     -> translate_ident vars args x

 | Expr_array el                    -> Array (List.map (translate_expr vars args) el)

 | Expr_access (t, i)               -> Access (translate_expr vars args t, translate_expr vars args (expr_of_dimension i))

 | Expr_power  (e, n)               -> Power  (translate_expr vars args e, translate_expr vars args (expr_of_dimension n))

 | Expr_tuple _

 | Expr_arrow _ 

 | Expr_fby _

 | Expr_pre _                       -> (Printers.pp_expr Format.err_formatter expr; Format.pp_print_flush Format.err_formatter (); raise NormalizationError)

 | Expr_when    (e1, _, _)          -> translate_expr vars args e1

 | Expr_merge   (x, _)              -> raise NormalizationError

 | Expr_appl (id, e, _) when Basic_library.is_internal_fun id ->

   let nd = node_from_name id in

   (match e.expr_desc with

   | Expr_tuple el -> Fun (node_name nd, List.map (translate_expr vars args) el)

   | _             -> Fun (node_name nd, [translate_expr vars args e]))

 | Expr_ite (g,t,e) -> (

   (* special treatment depending on the active backend. For horn backend or

      acsl spec, ite are preserved in expression. While they are removed for C

      or Java backends. *)

     Fun ("ite", [translate_expr vars args g; translate_expr vars args t; translate_expr vars args e])

 )

 | _                   -> raise NormalizationError

let translate_guard node args expr =

  match expr.expr_desc with

  | Expr_ident x  -> translate_ident node args x

  | _ -> assert false

let rec translate_act node ((m, si, j, d, s) as args) (y, expr) =

  match expr.expr_desc with

  | Expr_ite   (c, t, e) -> let g = translate_guard node args c in

			    conditional g [translate_act node args (y, t)]

                              [translate_act node args (y, e)]

  | Expr_merge (x, hl)   -> MBranch (translate_ident node args x, List.map (fun (t,  h) -> t, [translate_act node args (y, h)]) hl)

  | _                    -> MLocalAssign (y, translate_expr node args expr)

let reset_instance vars args i r c =

  match r with

  | None        -> []

  | Some (x, l) -> [control_on_clock vars args c (MBranch (translate_ident vars args x, [l, [MReset i]]))]

let translate_eq node keep_ite (local_vars: var_decl list) ((m, si, j, d, s) as args) eq =

  (*Format.eprintf "translate_eq %a@." Printers.pp_node_eq eq;*)

  let vars = local_vars@(node_vars node) in

  let get_var x = 

    let test v = v.var_id = x in

    if List.exists test vars then List.find test vars else assert false in

  match eq.eq_lhs, eq.eq_rhs.expr_desc with

  | [x], Expr_arrow (e1, e2)                     ->

    let var_x = get_var x in

    let o = new_instance node arrow_top_decl eq.eq_rhs.expr_tag in

    let c1 = translate_expr vars args e1 in

    let c2 = translate_expr vars args e2 in

    (m,

     MReset o :: si,

     Utils.IMap.add o (arrow_top_decl, []) j,

     d,

     (control_on_clock vars args eq.eq_rhs.expr_clock (MStep ([var_x], o, [c1;c2]))) :: s)

  | [x], Expr_pre e1 when ISet.mem (get_var x) d     ->

    let var_x = get_var x in

    (ISet.add var_x m,

     si,

     j,

     d,

     control_on_clock vars args eq.eq_rhs.expr_clock (MStateAssign (var_x, translate_expr vars args e1)) :: s)

  | [x], Expr_fby (e1, e2) when ISet.mem (get_var x) d ->

    let var_x = get_var x in

    (ISet.add var_x m,

     MStateAssign (var_x, translate_expr vars args e1) :: si,

     j,

     d,

     control_on_clock vars args eq.eq_rhs.expr_clock (MStateAssign (var_x, translate_expr vars args e2)) :: s)

  | p, Expr_appl (f, arg, r)                  ->

    let var_p = List.map (fun v -> get_var v) p in

    let el =

      match arg.expr_desc with

      | Expr_tuple el -> el

      | _             -> [arg] in

    let vl = List.map (translate_expr vars args) el in

    let node_f = node_from_name f in

    let call_f =

      node_f,

      NodeDep.filter_static_inputs (node_inputs node_f) el in 

    let o = new_instance node node_f eq.eq_rhs.expr_tag in

    (m,

     (if is_stateless_node node_f then si else MReset o :: si),

     (if Basic_library.is_internal_fun f then j else Utils.IMap.add o call_f j),

     d,

     reset_instance vars args o r eq.eq_rhs.expr_clock @

       (control_on_clock vars args eq.eq_rhs.expr_clock (MStep (var_p, o, vl))) :: s)

   (* special treatment depending on the active backend. For horn backend, x = ite (g,t,e)

      are preserved. While they are replaced as if g then x = t else x = e in  C or Java

      backends. *)

  | [x], Expr_ite   (c, t, e) when keep_ite     -> 

    let var_x = get_var x in

    (m, 

     si, 

     j, 

     d, 

     (control_on_clock vars args eq.eq_rhs.expr_clock 

	(MLocalAssign (var_x, translate_expr vars args eq.eq_rhs))::s)

    )

  | [x], _                                       -> (

    let var_x = get_var x in

    (m, si, j, d, 

     control_on_clock vars args eq.eq_rhs.expr_clock (translate_act vars args (var_x, eq.eq_rhs)) :: s)

  )

  | _                                            ->

    begin

      Format.eprintf "unsupported equation: %a@?" Printers.pp_node_eq eq;

      assert false

    end

let translate_eqs node keep_ite local_vars args eqs =

  List.fold_right (fun eq args -> translate_eq node keep_ite local_vars args eq) eqs args;;

(* The eexpr shoud have been normalized, ie. its eexpr_normalized field updated

   We add a new boolean output var and bound it to the main expression

   characterizing the eexpr.

*)

let translate_eexpr nd eexpr =

  (* Format.eprintf "Translating eexpr: %a" Printers.pp_eexpr eexpr; *)

  let output_var, eqs, locals = match eexpr.eexpr_normalized with None -> assert false | Some x -> x in 

  (* both inputs and outputs are considered here as inputs for the specification *) 

  let inputs = nd.node_inputs @ nd.node_outputs in

  let inputs_quantifiers = inputs @ (List.flatten (List.map snd eexpr.eexpr_quantifiers)) in 

  let eexpr_local_vars = output_var :: locals @ (List.flatten (List.map snd eexpr.eexpr_quantifiers)) in

  let visible_vars = eexpr_local_vars @ inputs in

  let sort_eqs inputs eqs = 

    let eqs_logic, new_locals_logic, sch_logic = Scheduling.schedule_eqs inputs visible_vars eqs in

    (* Format.eprintf "sch: [%a]@;new locals: [%a]@;locals:[%a]@.eexpr local vars: [%a]@.@?"  *)

    (*   (Utils.fprintf_list ~sep:", " Format.pp_print_string) sch_logic *)

    (*   (Utils.fprintf_list ~sep:", " Printers.pp_var) new_locals_logic *)

    (*   (Utils.fprintf_list ~sep:", " Printers.pp_var) locals *)

    (*   (Utils.fprintf_list ~sep:", " Printers.pp_var) eexpr_local_vars;  *)

    let locals = eexpr_local_vars @ new_locals_logic @ (List.flatten (List.map snd eexpr.eexpr_quantifiers)) in

    let sorted_eqs_rev_logic, remainder_logic = 

      List.fold_left 

	(fun (accu, eqs_remainder) v -> 

	  if List.exists (fun eq -> List.mem v eq.eq_lhs) accu

	  then (* The variable was already handled by a previous selected eq. 

		  Typically it is part of a tuple *)

	    ((* Format.eprintf "Case 1 for variable %s@." v; *)

	     (accu, eqs_remainder)

	    )

	  else if List.exists (fun vdecl -> vdecl.var_id = v) locals || output_var.var_id = v

	  then ((* Select the eq associated to v. *) 

	    (* Format.eprintf "Case 2 for variable %s@." v; *)

	    let eq_v, remainder = find_eq v eqs_remainder in

	    eq_v::accu, remainder

	  )

	  else ((* else it is a constant value, checked during typing phase *)

	    (* Format.eprintf "Case 3 for variable %s@." v; *)

	    accu, eqs_remainder

	  )

	) 

	([], eqs_logic) 

	sch_logic 

    in

    if List.length remainder_logic > 0 then (

      Format.eprintf "Spec equations not used are@.%a@.Full equation set is:@.%a@.@?"

	Printers.pp_node_eqs remainder_logic

	Printers.pp_node_eqs eqs_logic;

      assert false );

    List.rev sorted_eqs_rev_logic, locals  

  in

  (* Generating logic definition instructions *)

  let sorted_eqs, locals = sort_eqs inputs_quantifiers eqs in

  let init_args = 

    ISet.empty, 

    [], 

    Utils.IMap.empty, 

    List.fold_right (fun l -> ISet.add l) locals ISet.empty,

    [] 

  in

  let m, init, j, locals, s_logic = 

    translate_eqs nd true (* keep_ite *)  eexpr_local_vars init_args (sorted_eqs) 

  in

  let s_logic = List.filter (fun i -> match i with MStateAssign _ -> false | _ -> true) s_logic in 

  let _,_,_,_, s_side_effects = 

    translate_eqs nd false (* explose ite *)  eexpr_local_vars init_args (sorted_eqs) 

  in

  let s_side_effects = 

    List.filter (fun i -> 

      match i with

      | MStep([v], _, _) 

      | MLocalAssign(v,_) -> v.var_id <> output_var.var_id 

      | _ -> true) s_side_effects in 

  {

    muid = eexpr.eexpr_tag;

    mquantifiers = eexpr.eexpr_quantifiers;

    mmmemory = ISet.elements m;

    mmcalls = []; (* no calls *)

    mminstances = []; (* no calls *)

    mminit = init;

    mmstep_logic = {

      step_inputs = inputs;

      step_outputs = [output_var];

      step_locals = ISet.elements (ISet.remove output_var (ISet.diff locals m));

      step_checks = [] (* Not handled yet *);

      step_instrs = (

	(* special treatment depending on the active backend. For horn backend,

	   common branches are not merged while they are in C or Java

	   backends. *)

	match !Options.output with

	| "horn" -> s_logic

	| "C" | "java" | _ -> join_guards_list s_logic

      )

    };

    mmstep_effects = {

      step_inputs = inputs;

      step_outputs = [];

      step_locals = ISet.elements (ISet.remove output_var (ISet.diff locals m));

      step_checks = [] (* Not handled yet *);

      step_instrs = (

	(* special treatment depending on the active backend. For horn backend,

	   common branches are not merged while they are in C or Java

	   backends. *)

	match !Options.output with

	| "horn" -> s_side_effects

	| "C" | "java" | _ -> join_guards_list s_side_effects

      )

    }

  }    

let translate_spec nd spec = 

  (* Each eexpr of the spec is expressed as a minimachine: 

     instrs (to update memory and set local vars) 

     + expr (to compute the output

     + memory defs 

     + instances (for callee nodes)

  *)

  let transl = List.map (translate_eexpr nd) in

  {

    m_requires = transl spec.requires;

    m_ensures = transl spec.ensures;

    m_behaviors =

      List.map

	(fun (beh_id, req, ens, _) -> beh_id, transl req, transl ens) 

	spec.behaviors

  }

let translate_decl top =

  let nd = match top.top_decl_desc with Node nd -> nd | _ -> assert false in

  (*Log.report ~level:1 (fun fmt -> Printers.pp_node fmt nd);*)

  let nd, sch = Scheduling.schedule_node nd in

  (* Format.eprintf "node sch: [%a]@.@?"  *)

  (*   (Utils.fprintf_list ~sep:", " Format.pp_print_string) sch;  *)

  (* let split_eqs = Splitting.tuple_split_eq_list nd.node_eqs in *)

  let sorted_eqs_rev, remainder = 

    List.fold_left 

      (fun (accu, node_eqs_remainder) v -> 

	if List.exists (fun eq -> List.mem v eq.eq_lhs) accu

	then (* The variable was already handled by a previous selected eq. 

		Typically it is part of a tuple *)

	  (accu, node_eqs_remainder)

	else

	  if   List.exists (fun vdecl -> vdecl.var_id = v) nd.node_locals

	    || List.exists (fun vdecl -> vdecl.var_id = v) nd.node_outputs

	  then (* Select the eq associated to v. *)

	    let eq_v, remainder = find_eq v node_eqs_remainder in

	    eq_v::accu, remainder

	  else (* else it is a constant value, checked during typing phase *)

	    accu, node_eqs_remainder

      ) 

      ([], nd.node_eqs) 

      sch 

  in

  if List.length remainder > 0 then (

    Format.eprintf "Equations not used are@.%a@.Full equation set is:@.%a@.@?"

      Printers.pp_node_eqs remainder

      Printers.pp_node_eqs nd.node_eqs;

    assert false )

  ;

  let init_args = ISet.empty, [], Utils.IMap.empty, List.fold_right (fun l -> ISet.add l) nd.node_locals ISet.empty, [] in

  let keep_ite = (match !Options.output with | "horn" -> true | "C" | "java" | _ -> false) in

  let m, init, j, locals, s = translate_eqs nd keep_ite [] init_args (List.rev sorted_eqs_rev) in

  let mmap = Utils.IMap.fold (fun i n res -> (i, n)::res) j [] in

  {

    mname = nd;

    mmemory = ISet.elements m;

    mcalls = mmap;

      minstances = List.filter (fun (_, (n,_)) -> not (is_stateless_node n)) mmap;

    minit = init;

    mstatic = List.filter (fun v -> v.var_dec_const) nd.node_inputs;

    mstep = {

      step_inputs = nd.node_inputs;

      step_outputs = nd.node_outputs;

      step_locals = ISet.elements (ISet.diff locals m);

      step_checks = List.map (fun d -> d.Dimension.dim_loc, translate_expr (node_vars nd) init_args (expr_of_dimension d)) nd.node_checks;

      step_instrs = (

	(* special treatment depending on the active backend. For horn backend,

	   common branches are not merged while they are in C or Java

	   backends. *)

	match !Options.output with

	| "horn" -> s

	| "C" | "java" | _ -> join_guards_list s

      );

    };

    mspec = Utils.option_map (translate_spec nd) nd.node_spec;

    mannot = List.flatten (

      List.map (fun ann -> List.map (fun (kwd, eexpr) -> kwd, (translate_eexpr nd eexpr)) ann.annots) nd.node_annot);

  }

let translate_prog decls = 

  let nodes = get_nodes decls in 

   arrow_machine ::  List.map translate_decl nodes

let get_machine_opt name machines =  

  List.fold_left 

    (fun res m -> 

      match res with 

      | Some _ -> res 

      | None -> if m.mname.node_id = name then Some m else None)

    None machines

(* Local Variables: *)

(* compile-command:"make -C .." *)

(* End: *)