Project

General

Profile

Statistics
| Branch: | Tag: | Revision:

lustrec / src / typing.ml @ 15003796

History | View | Annotate | Download (30.6 KB)

1
(********************************************************************)
2
(*                                                                  *)
3
(*  The LustreC compiler toolset   /  The LustreC Development Team  *)
4
(*  Copyright 2012 -    --   ONERA - CNRS - INPT - LIFL             *)
5
(*                                                                  *)
6
(*  LustreC is free software, distributed WITHOUT ANY WARRANTY      *)
7
(*  under the terms of the GNU Lesser General Public License        *)
8
(*  version 2.1.                                                    *)
9
(*                                                                  *) 
10
(*  This file was originally from the Prelude compiler              *)
11
(*                                                                  *) 
12
(********************************************************************)
13

    
14
(** Main typing module. Classic inference algorithm with destructive
15
    unification. *)
16

    
17
let debug fmt args = () (* Format.eprintf "%a"  *)
18
(* Though it shares similarities with the clock calculus module, no code
19
    is shared.  Simple environments, very limited identifier scoping, no
20
    identifier redefinition allowed. *)
21

    
22
open Utils
23
(* Yes, opening both modules is dirty as some type names will be
24
   overwritten, yet this makes notations far lighter.*)
25
open LustreSpec
26
open Corelang
27
open Types
28
open Format
29

    
30
let pp_typing_env fmt env =
31
  Env.pp_env print_ty fmt env
32

    
33
(** [occurs tvar ty] returns true if the type variable [tvar] occurs in
34
    type [ty]. False otherwise. *)
35
let rec occurs tvar ty =
36
  let ty = repr ty in
37
  match ty.tdesc with
38
  | Tvar -> ty=tvar
39
  | Tarrow (t1, t2) ->
40
      (occurs tvar t1) || (occurs tvar t2)
41
  | Ttuple tl ->
42
     List.exists (occurs tvar) tl
43
  | Tstruct fl ->
44
     List.exists (fun (f, t) -> occurs tvar t) fl
45
  | Tarray (_, t)
46
  | Tstatic (_, t)
47
  | Tclock t
48
  | Tlink t -> occurs tvar t
49
  | Tenum _ | Tconst _ | Tunivar | Tint | Treal | Tbool | Trat -> false
50

    
51
(** Promote monomorphic type variables to polymorphic type variables. *)
52
(* Generalize by side-effects *)
53
let rec generalize ty =
54
  match ty.tdesc with
55
  | Tvar ->
56
      (* No scopes, always generalize *)
57
      ty.tdesc <- Tunivar
58
  | Tarrow (t1,t2) ->
59
      generalize t1; generalize t2
60
  | Ttuple tl ->
61
     List.iter generalize tl
62
  | Tstruct fl ->
63
     List.iter (fun (f, t) -> generalize t) fl
64
  | Tstatic (d, t)
65
  | Tarray (d, t) -> Dimension.generalize d; generalize t
66
  | Tclock t
67
  | Tlink t ->
68
      generalize t
69
  | Tenum _ | Tconst _ | Tunivar | Tint | Treal | Tbool | Trat -> ()
70

    
71
(** Downgrade polymorphic type variables to monomorphic type variables *)
72
let rec instantiate inst_vars inst_dim_vars ty =
73
  let ty = repr ty in
74
  match ty.tdesc with
75
  | Tenum _ | Tconst _ | Tvar | Tint | Treal | Tbool | Trat -> ty
76
  | Tarrow (t1,t2) ->
77
      {ty with tdesc =
78
       Tarrow ((instantiate inst_vars inst_dim_vars t1), (instantiate inst_vars inst_dim_vars t2))}
79
  | Ttuple tlist ->
80
      {ty with tdesc = Ttuple (List.map (instantiate inst_vars inst_dim_vars) tlist)}
81
  | Tstruct flist ->
82
      {ty with tdesc = Tstruct (List.map (fun (f, t) -> (f, instantiate inst_vars inst_dim_vars t)) flist)}
83
  | Tclock t ->
84
	{ty with tdesc = Tclock (instantiate inst_vars inst_dim_vars t)}
85
  | Tstatic (d, t) ->
86
	{ty with tdesc = Tstatic (Dimension.instantiate inst_dim_vars d, instantiate inst_vars inst_dim_vars t)}
87
  | Tarray (d, t) ->
88
	{ty with tdesc = Tarray (Dimension.instantiate inst_dim_vars d, instantiate inst_vars inst_dim_vars t)}
89
  | Tlink t ->
90
	(* should not happen *)
91
	{ty with tdesc = Tlink (instantiate inst_vars inst_dim_vars t)}
92
  | Tunivar ->
93
      try
94
        List.assoc ty.tid !inst_vars
95
      with Not_found ->
96
        let var = new_var () in
97
	inst_vars := (ty.tid, var)::!inst_vars;
98
	var
99

    
100
(* [type_coretype cty] types the type declaration [cty] *)
101
let rec type_coretype type_dim cty =
102
  match (*get_repr_type*) cty with
103
  | Tydec_any -> new_var ()
104
  | Tydec_int -> Type_predef.type_int
105
  | Tydec_real -> Type_predef.type_real
106
  | Tydec_float -> Type_predef.type_real
107
  | Tydec_bool -> Type_predef.type_bool
108
  | Tydec_clock ty -> Type_predef.type_clock (type_coretype type_dim ty)
109
  | Tydec_const c -> Type_predef.type_const c
110
  | Tydec_enum tl -> Type_predef.type_enum tl
111
  | Tydec_struct fl -> Type_predef.type_struct (List.map (fun (f, ty) -> (f, type_coretype type_dim ty)) fl)
112
  | Tydec_array (d, ty) ->
113
    begin
114
      let d = Dimension.copy (ref []) d in
115
      type_dim d;
116
      Type_predef.type_array d (type_coretype type_dim ty)
117
    end
118

    
119
(* [coretype_type] is the reciprocal of [type_typecore] *)
120
let rec coretype_type ty =
121
 match (repr ty).tdesc with
122
 | Tvar           -> Tydec_any
123
 | Tint           -> Tydec_int
124
 | Treal          -> Tydec_real
125
 | Tbool          -> Tydec_bool
126
 | Tconst c       -> Tydec_const c
127
 | Tclock t       -> Tydec_clock (coretype_type t)
128
 | Tenum tl       -> Tydec_enum tl
129
 | Tstruct fl     -> Tydec_struct (List.map (fun (f, t) -> (f, coretype_type t)) fl)
130
 | Tarray (d, t)  -> Tydec_array (d, coretype_type t)
131
 | Tstatic (_, t) -> coretype_type t
132
 | _         -> assert false
133

    
134
let get_coretype_definition tname =
135
  try
136
    let top = Hashtbl.find type_table (Tydec_const tname) in
137
    match top.top_decl_desc with
138
    | TypeDef tdef -> tdef.tydef_desc
139
    | _ -> assert false
140
  with Not_found -> raise (Error (Location.dummy_loc, Unbound_type tname))
141

    
142
let get_type_definition tname =
143
    type_coretype (fun d -> ()) (get_coretype_definition tname)
144

    
145
(* Equality on ground types only *)
146
(* Should be used between local variables which must have a ground type *)
147
let rec eq_ground t1 t2 =
148
  let t1 = repr t1 in
149
  let t2 = repr t2 in
150
  t1==t2 ||
151
  match t1.tdesc, t2.tdesc with
152
  | Tint, Tint | Tbool, Tbool | Trat, Trat | Treal, Treal -> true
153
  | Tenum tl, Tenum tl' when tl == tl' -> true
154
  | Ttuple tl, Ttuple tl' when List.length tl = List.length tl' -> List.for_all2 eq_ground tl tl'
155
  | Tstruct fl, Tstruct fl' when List.map fst fl = List.map fst fl' -> List.for_all2 (fun (_, t) (_, t') -> eq_ground t t') fl fl'
156
  | (Tconst t, _) ->
157
    let def_t = get_type_definition t in
158
    eq_ground def_t t2
159
  | (_, Tconst t)  ->
160
    let def_t = get_type_definition t in
161
    eq_ground t1 def_t
162
  | Tarrow (t1,t2), Tarrow (t1',t2') -> eq_ground t1 t1' && eq_ground t2 t2'
163
  | Tclock t1', Tclock t2' -> eq_ground t1' t2'
164
  | Tstatic (e1, t1'), Tstatic (e2, t2')
165
  | Tarray (e1, t1'), Tarray (e2, t2') -> Dimension.is_eq_dimension e1 e2 && eq_ground t1' t2'
166
  | _ -> false
167

    
168
(** [unify t1 t2] unifies types [t1] and [t2]
169
    using standard destructive unification.
170
    Raises [Unify (t1,t2)] if the types are not unifiable.
171
    [t1] is a expected/formal/spec type, [t2] is a computed/real/implem type,
172
    so in case of unification error: expected type [t1], got type [t2].
173
    If [sub]-typing is allowed, [t2] may be a subtype of [t1].
174
    If [semi] unification is required,
175
    [t1] should furthermore be an instance of [t2]
176
    and constants are handled differently.*)
177
let unify ?(sub=false) ?(semi=false) t1 t2 =
178
  let rec unif t1 t2 =
179
    let t1 = repr t1 in
180
    let t2 = repr t2 in
181
    if t1==t2 then
182
      ()
183
    else
184
      match t1.tdesc,t2.tdesc with
185
      (* strictly subtyping cases first *)
186
      | _ , Tclock t2 when sub && (get_clock_base_type t1 = None) ->
187
	unif t1 t2
188
      | _ , Tstatic (d2, t2) when sub && (get_static_value t1 = None) ->
189
	unif t1 t2
190
      (* This case is not mandatory but will keep "older" types *)
191
      | Tvar, Tvar ->
192
        if t1.tid < t2.tid then
193
          t2.tdesc <- Tlink t1
194
        else
195
          t1.tdesc <- Tlink t2
196
      | Tvar, _ when (not semi) && (not (occurs t1 t2)) ->
197
        t1.tdesc <- Tlink t2
198
      | _, Tvar when (not (occurs t2 t1)) ->
199
        t2.tdesc <- Tlink t1
200
      | Tarrow (t1,t2), Tarrow (t1',t2') ->
201
	begin
202
          unif t2 t2';
203
	  unif t1' t1
204
	end
205
      | Ttuple tl, Ttuple tl' when List.length tl = List.length tl' ->
206
	List.iter2 unif tl tl'
207
      | Ttuple [t1]        , _                  -> unif t1 t2
208
      | _                  , Ttuple [t2]        -> unif t1 t2
209
      | Tstruct fl, Tstruct fl' when List.map fst fl = List.map fst fl' ->
210
	List.iter2 (fun (_, t) (_, t') -> unif t t') fl fl'
211
      | Tclock _, Tstatic _
212
      | Tstatic _, Tclock _ -> raise (Unify (t1, t2))
213
      | Tclock t1', Tclock t2' -> unif t1' t2'
214
      | Tint, Tint | Tbool, Tbool | Trat, Trat | Treal, Treal
215
      | Tunivar, _ | _, Tunivar -> ()
216
      | (Tconst t, _) ->
217
	let def_t = get_type_definition t in
218
	unif def_t t2
219
      | (_, Tconst t)  ->
220
	let def_t = get_type_definition t in
221
	unif t1 def_t
222
      | Tenum tl, Tenum tl' when tl == tl' -> ()
223
      | Tstatic (e1, t1'), Tstatic (e2, t2')
224
      | Tarray (e1, t1'), Tarray (e2, t2') ->
225
	let eval_const =
226
	  if semi
227
	  then (fun c -> Some (Dimension.mkdim_ident Location.dummy_loc c))
228
	  else (fun c -> None) in
229
	begin
230
	  unif t1' t2';
231
	  Dimension.eval Basic_library.eval_env eval_const e1;
232
	  Dimension.eval Basic_library.eval_env eval_const e2;
233
	  Dimension.unify ~semi:semi e1 e2;
234
	end
235
      | _,_ -> raise (Unify (t1, t2))
236
  in unif t1 t2
237

    
238
(* Expected type ty1, got type ty2 *)
239
let try_unify ?(sub=false) ?(semi=false) ty1 ty2 loc =
240
  try
241
    unify ~sub:sub ~semi:semi ty1 ty2
242
  with
243
  | Unify _ ->
244
    raise (Error (loc, Type_clash (ty1,ty2)))
245
  | Dimension.Unify _ ->
246
    raise (Error (loc, Type_clash (ty1,ty2)))
247

    
248
let rec type_struct_const_field loc (label, c) =
249
  if Hashtbl.mem field_table label
250
  then let tydef = Hashtbl.find field_table label in
251
       let tydec = (typedef_of_top tydef).tydef_desc in 
252
       let tydec_struct = get_struct_type_fields tydec in
253
       let ty_label = type_coretype (fun d -> ()) (List.assoc label tydec_struct) in
254
       begin
255
	 try_unify ty_label (type_const loc c) loc;
256
	 type_coretype (fun d -> ()) tydec
257
       end
258
  else raise (Error (loc, Unbound_value ("struct field " ^ label)))
259

    
260
and type_const loc c = 
261
  match c with
262
  | Const_int _     -> Type_predef.type_int
263
  | Const_real _    -> Type_predef.type_real
264
  | Const_float _   -> Type_predef.type_real
265
  | Const_array ca  -> let d = Dimension.mkdim_int loc (List.length ca) in
266
		      let ty = new_var () in
267
		      List.iter (fun e -> try_unify ty (type_const loc e) loc) ca;
268
		      Type_predef.type_array d ty
269
  | Const_tag t     ->
270
    if Hashtbl.mem tag_table t
271
    then 
272
      let tydef = typedef_of_top (Hashtbl.find tag_table t) in
273
      let tydec =
274
	if is_user_type tydef.tydef_desc
275
	then Tydec_const tydef.tydef_id
276
	else tydef.tydef_desc in
277
      type_coretype (fun d -> ()) tydec
278
    else raise (Error (loc, Unbound_value ("enum tag " ^ t)))
279
  | Const_struct fl ->
280
    let ty_struct = new_var () in
281
    begin
282
      let used =
283
	List.fold_left
284
	  (fun acc (l, c) ->
285
	    if List.mem l acc
286
	    then raise (Error (loc, Already_bound ("struct field " ^ l)))
287
	    else try_unify ty_struct (type_struct_const_field loc (l, c)) loc; l::acc)
288
	  [] fl in
289
      try
290
	let total = List.map fst (get_struct_type_fields (coretype_type ty_struct)) in
291
(*	List.iter (fun l -> Format.eprintf "total: %s@." l) total;
292
	List.iter (fun l -> Format.eprintf "used: %s@." l) used; *)
293
	let undef = List.find (fun l -> not (List.mem l used)) total
294
	in raise (Error (loc, Unbound_value ("struct field " ^ undef)))
295
      with Not_found -> 
296
	ty_struct
297
    end
298
  | Const_string _ -> assert false (* string should only appear in annotations *)
299

    
300
(* The following typing functions take as parameter an environment [env]
301
   and whether the element being typed is expected to be constant [const]. 
302
   [env] is a pair composed of:
303
  - a map from ident to type, associating to each ident, i.e. 
304
    variables, constants and (imported) nodes, its type including whether
305
    it is constant or not. This latter information helps in checking constant 
306
    propagation policy in Lustre.
307
  - a vdecl list, in order to modify types of declared variables that are
308
    later discovered to be clocks during the typing process.
309
*)
310
let check_constant loc const_expected const_real =
311
  if const_expected && not const_real
312
  then raise (Error (loc, Not_a_constant))
313

    
314
let rec type_add_const env const arg targ =
315
(*Format.eprintf "Typing.type_add_const %a %a@." Printers.pp_expr arg Types.print_ty targ;*)
316
  if const
317
  then let d =
318
	 if is_dimension_type targ
319
	 then dimension_of_expr arg
320
	 else Dimension.mkdim_var () in
321
       let eval_const id = Types.get_static_value (Env.lookup_value (fst env) id) in
322
       Dimension.eval Basic_library.eval_env eval_const d;
323
       let real_static_type = Type_predef.type_static d (Types.dynamic_type targ) in
324
       (match Types.get_static_value targ with
325
       | None    -> ()
326
       | Some d' -> try_unify targ real_static_type arg.expr_loc);
327
       real_static_type
328
  else targ
329

    
330
(* emulates a subtyping relation between types t and (d : t),
331
   used during node applications and assignments *)
332
and type_subtyping_arg env in_main ?(sub=true) const real_arg formal_type =
333
  let loc = real_arg.expr_loc in
334
  let const = const || (Types.get_static_value formal_type <> None) in
335
  let real_type = type_add_const env const real_arg (type_expr env in_main const real_arg) in
336
  (*Format.eprintf "subtyping const %B real %a:%a vs formal %a@." const Printers.pp_expr real_arg Types.print_ty real_type Types.print_ty formal_type;*)
337
  try_unify ~sub:sub formal_type real_type loc
338

    
339
and type_ident env in_main loc const id =
340
  type_expr env in_main const (expr_of_ident id loc)
341

    
342
(* typing an application implies:
343
   - checking that const formal parameters match real const (maybe symbolic) arguments
344
   - checking type adequation between formal and real arguments
345
   An application may embed an homomorphic/internal function, in which case we need to split
346
   it in many calls
347
*)
348
and type_appl env in_main loc const f args =
349
  let targs = List.map (type_expr env in_main const) args in
350
  if Basic_library.is_internal_fun f && List.exists is_tuple_type targs
351
  then
352
    try
353
      let targs = Utils.transpose_list (List.map type_list_of_type targs) in
354
      Types.type_of_type_list (List.map (type_simple_call env in_main loc const f) targs)
355
    with
356
      Utils.TransposeError (l, l') -> raise (Error (loc, WrongMorphism (l, l')))
357
  else
358
    type_dependent_call env in_main loc const f (List.combine args targs)
359

    
360
(* type a call with possible dependent types. [targs] is here a list of (argument, type) pairs. *)
361
and type_dependent_call env in_main loc const f targs =
362
(*Format.eprintf "Typing.type_dependent_call %s@." f;*)
363
  let tins, touts = new_var (), new_var () in
364
  let tfun = Type_predef.type_arrow tins touts in
365
  type_subtyping_arg env in_main const (expr_of_ident f loc) tfun;
366
  let tins = type_list_of_type tins in
367
  if List.length targs <> List.length tins then
368
    raise (Error (loc, WrongArity (List.length tins, List.length targs)))
369
  else
370
    begin
371
      List.iter2 (fun (a,t) ti ->
372
	let t' = type_add_const env (const || Types.get_static_value ti <> None) a t
373
	in try_unify ~sub:true ti t' a.expr_loc;
374
      ) targs tins;
375
(*Format.eprintf "Typing.type_dependent_call END@.";*)
376
      touts;
377
    end
378

    
379
(* type a simple call without dependent types 
380
   but possible homomorphic extension.
381
   [targs] is here a list of arguments' types. *)
382
and type_simple_call env in_main loc const f targs =
383
  let tins, touts = new_var (), new_var () in
384
  let tfun = Type_predef.type_arrow tins touts in
385
  type_subtyping_arg env in_main const (expr_of_ident f loc) tfun;
386
  (*Format.eprintf "try unify %a %a@." Types.print_ty tins Types.print_ty (type_of_type_list targs);*)
387
  try_unify ~sub:true tins (type_of_type_list targs) loc;
388
  touts
389

    
390
(** [type_expr env in_main expr] types expression [expr] in environment
391
    [env], expecting it to be [const] or not. *)
392
and type_expr env in_main const expr =
393
  (* typing also the possible annotations *)
394
  let _ = (
395
    match expr.expr_annot with
396
      None -> () 
397
    | Some anns -> type_expr_annot env in_main const anns
398
  ) in
399
  let resulting_ty = 
400
    match expr.expr_desc with
401
  | Expr_const c ->
402
    let ty = type_const expr.expr_loc c in
403
    let ty = Type_predef.type_static (Dimension.mkdim_var ()) ty in
404
    expr.expr_type <- ty;
405
    ty
406
  | Expr_ident v ->
407
    let tyv =
408
      try
409
        Env.lookup_value (fst env) v
410
      with Not_found ->
411
	Format.eprintf "Failure in typing expr %a@." Printers.pp_expr expr;
412
        raise (Error (expr.expr_loc, Unbound_value ("identifier " ^ v)))
413
    in
414
    let ty = instantiate (ref []) (ref []) tyv in
415
    let ty' =
416
      if const
417
      then Type_predef.type_static (Dimension.mkdim_var ()) (new_var ())
418
      else new_var () in
419
    try_unify ty ty' expr.expr_loc;
420
    expr.expr_type <- ty;
421
    ty 
422
  | Expr_array elist ->
423
    let ty_elt = new_var () in
424
    List.iter (fun e -> try_unify ty_elt (type_appl env in_main expr.expr_loc const "uminus" [e]) e.expr_loc) elist;
425
    let d = Dimension.mkdim_int expr.expr_loc (List.length elist) in
426
    let ty = Type_predef.type_array d ty_elt in
427
    expr.expr_type <- ty;
428
    ty
429
  | Expr_access (e1, d) ->
430
    type_subtyping_arg env in_main true (expr_of_dimension d) Type_predef.type_int;
431
    let ty_elt = new_var () in
432
    let d = Dimension.mkdim_var () in
433
    type_subtyping_arg env in_main const e1 (Type_predef.type_array d ty_elt);
434
    expr.expr_type <- ty_elt;
435
    ty_elt
436
  | Expr_power (e1, d) ->
437
    let eval_const id = Types.get_static_value (Env.lookup_value (fst env) id) in
438
    type_subtyping_arg env in_main true (expr_of_dimension d) Type_predef.type_int;
439
    Dimension.eval Basic_library.eval_env eval_const d;
440
    let ty_elt = type_appl env in_main expr.expr_loc const "uminus" [e1] in
441
    let ty = Type_predef.type_array d ty_elt in
442
    expr.expr_type <- ty;
443
    ty
444
  | Expr_tuple elist ->
445
    let ty = new_ty (Ttuple (List.map (type_expr env in_main const) elist)) in
446
    expr.expr_type <- ty;
447
    ty
448
  | Expr_ite (c, t, e) ->
449
    type_subtyping_arg env in_main const c Type_predef.type_bool;
450
    let ty = type_appl env in_main expr.expr_loc const "+" [t; e] in
451
    expr.expr_type <- ty;
452
    ty
453
  | Expr_appl (id, args, r) ->
454
    (* application of non internal function is not legal in a constant
455
       expression *)
456
    (match r with
457
    | None        -> ()
458
    | Some c -> 
459
      check_constant expr.expr_loc const false;	
460
      type_subtyping_arg env in_main const c Type_predef.type_bool);
461
    let touts = type_appl env in_main expr.expr_loc const id (expr_list_of_expr args) in
462
    expr.expr_type <- touts;
463
    touts
464
  | Expr_fby (e1,e2)
465
  | Expr_arrow (e1,e2) ->
466
    (* fby/arrow is not legal in a constant expression *)
467
    check_constant expr.expr_loc const false;
468
    let ty = type_appl env in_main expr.expr_loc const "+" [e1; e2] in
469
    expr.expr_type <- ty;
470
    ty
471
  | Expr_pre e ->
472
    (* pre is not legal in a constant expression *)
473
    check_constant expr.expr_loc const false;
474
    let ty = type_appl env in_main expr.expr_loc const "uminus" [e] in
475
    expr.expr_type <- ty;
476
    ty
477
  | Expr_when (e1,c,l) ->
478
    (* when is not legal in a constant expression *)
479
    check_constant expr.expr_loc const false;
480
    let typ_l = Type_predef.type_clock (type_const expr.expr_loc (Const_tag l)) in
481
    let expr_c = expr_of_ident c expr.expr_loc in
482
    type_subtyping_arg env in_main ~sub:false const expr_c typ_l;
483
    let ty = type_appl env in_main expr.expr_loc const "uminus" [e1] in
484
    expr.expr_type <- ty;
485
    ty
486
  | Expr_merge (c,hl) ->
487
    (* merge is not legal in a constant expression *)
488
    check_constant expr.expr_loc const false;
489
    let typ_in, typ_out = type_branches env in_main expr.expr_loc const hl in
490
    let expr_c = expr_of_ident c expr.expr_loc in
491
    let typ_l = Type_predef.type_clock typ_in in
492
    type_subtyping_arg env in_main ~sub:false const expr_c typ_l;
493
    expr.expr_type <- typ_out;
494
    typ_out
495
  in 
496
  Log.report ~level:3 (fun fmt -> Format.fprintf fmt "Type of expr %a: %a@." Printers.pp_expr expr Types.print_ty resulting_ty);
497
  resulting_ty
498

    
499
and type_branches env in_main loc const hl =
500
  let typ_in = new_var () in
501
  let typ_out = new_var () in
502
  try
503
    let used_labels =
504
      List.fold_left (fun accu (t, h) ->
505
	unify typ_in (type_const loc (Const_tag t));
506
	type_subtyping_arg env in_main const h typ_out;
507
	if List.mem t accu
508
	then raise (Error (loc, Already_bound t))
509
	else t :: accu) [] hl in
510
    let type_labels = get_enum_type_tags (coretype_type typ_in) in
511
    if List.sort compare used_labels <> List.sort compare type_labels
512
    then let unbound_tag = List.find (fun t -> not (List.mem t used_labels)) type_labels in
513
	 raise (Error (loc, Unbound_value ("branching tag " ^ unbound_tag)))
514
    else (typ_in, typ_out)
515
  with Unify (t1, t2) ->
516
    raise (Error (loc, Type_clash (t1,t2)))
517

    
518

    
519
and type_eexpr env in_main const ee =
520
  let ty = type_expr env in_main const ee.eexpr_qfexpr in
521
  ee.eexpr_type <- ty;
522
  ty
523

    
524
and type_expr_annot env in_main const anns =
525
  List.iter (fun (_, ee) ->
526
    ignore (type_eexpr env in_main const ee)
527
  ) anns.annots
528
    
529

    
530
(** [type_eq env eq] types equation [eq] in environment [env] *)
531
let type_eq env in_main undefined_vars eq =
532
(*Format.eprintf "Typing.type_eq %a@." Printers.pp_node_eq eq;*)
533
  (* Check undefined variables, type lhs *)
534
  let expr_lhs = expr_of_expr_list eq.eq_loc (List.map (fun v -> expr_of_ident v eq.eq_loc) eq.eq_lhs) in
535
  let ty_lhs = type_expr env in_main false expr_lhs in
536
  (* Check multiple variable definitions *)
537
  let define_var id uvars =
538
    if ISet.mem id uvars
539
    then ISet.remove id uvars
540
    else raise (Error (eq.eq_loc, Already_defined id))
541
  in
542
  (* check assignment of declared constant, assignment of clock *)
543
  let ty_lhs =
544
    type_of_type_list
545
      (List.map2 (fun ty id ->
546
	if get_static_value ty <> None
547
	then raise (Error (eq.eq_loc, Assigned_constant id)) else
548
	match get_clock_base_type ty with
549
	| None -> ty
550
	| Some ty -> ty)
551
	 (type_list_of_type ty_lhs) eq.eq_lhs) in
552
  let undefined_vars =
553
    List.fold_left (fun uvars v -> define_var v uvars) undefined_vars eq.eq_lhs in
554
  (* Type rhs wrt to lhs type with subtyping, i.e. a constant rhs value may be assigned
555
     to a (always non-constant) lhs variable *)
556
  type_subtyping_arg env in_main false eq.eq_rhs ty_lhs;
557
  undefined_vars
558

    
559

    
560
(* [type_coreclock env ck id loc] types the type clock declaration [ck]
561
   in environment [env] *)
562
let type_coreclock env ck id loc =
563
  match ck.ck_dec_desc with
564
  | Ckdec_any | Ckdec_pclock (_,_) -> ()
565
  | Ckdec_bool cl ->
566
      let dummy_id_expr = expr_of_ident id loc in
567
      let when_expr =
568
        List.fold_left
569
          (fun expr (x, l) ->
570
                {expr_tag = new_tag ();
571
                 expr_desc= Expr_when (expr,x,l);
572
                 expr_type = new_var ();
573
                 expr_clock = Clocks.new_var true;
574
                 expr_delay = Delay.new_var ();
575
                 expr_loc=loc;
576
		 expr_annot = None})
577
          dummy_id_expr cl
578
      in
579
      ignore (type_expr env false false when_expr)
580

    
581
let rec check_type_declaration loc cty =
582
 match cty with
583
 | Tydec_clock ty
584
 | Tydec_array (_, ty) -> check_type_declaration loc ty
585
 | Tydec_const tname   ->
586
   if not (Hashtbl.mem type_table cty)
587
   then raise (Error (loc, Unbound_type tname));
588
 | _                   -> ()
589

    
590
let type_var_decl vd_env env vdecl =
591
(*Format.eprintf "Typing.type_var_decl START %a:%a@." Printers.pp_var vdecl Printers.print_dec_ty vdecl.var_dec_type.ty_dec_desc;*)
592
  check_type_declaration vdecl.var_loc vdecl.var_dec_type.ty_dec_desc;
593
  let eval_const id = Types.get_static_value (Env.lookup_value env id) in
594
  let type_dim d =
595
    begin
596
      type_subtyping_arg (env, vd_env) false true (expr_of_dimension d) Type_predef.type_int;
597

    
598
      Dimension.eval Basic_library.eval_env eval_const d;
599
    end in
600
  let ty = type_coretype type_dim vdecl.var_dec_type.ty_dec_desc in
601

    
602
  let ty_static =
603
    if vdecl.var_dec_const
604
    then  Type_predef.type_static (Dimension.mkdim_var ()) ty
605
    else ty in
606
  (match vdecl.var_dec_value with
607
  | None   -> ()
608
  | Some v -> type_subtyping_arg (env, vd_env) false ~sub:false true v ty_static);
609
  try_unify ty_static vdecl.var_type vdecl.var_loc;
610
  let new_env = Env.add_value env vdecl.var_id ty_static in
611
  type_coreclock (new_env,vd_env) vdecl.var_dec_clock vdecl.var_id vdecl.var_loc;
612
(*Format.eprintf "END %a@." Types.print_ty ty_static;*)
613
  new_env
614

    
615
let type_var_decl_list vd_env env l =
616
  List.fold_left (type_var_decl vd_env) env l
617

    
618
let type_of_vlist vars =
619
  let tyl = List.map (fun v -> v.var_type) vars in
620
  type_of_type_list tyl
621

    
622
let add_vdecl vd_env vdecl =
623
 if List.exists (fun v -> v.var_id = vdecl.var_id) vd_env
624
 then raise (Error (vdecl.var_loc, Already_bound vdecl.var_id))
625
 else vdecl::vd_env
626

    
627
let check_vd_env vd_env =
628
  ignore (List.fold_left add_vdecl [] vd_env)
629

    
630
(** [type_node env nd loc] types node [nd] in environment env. The
631
    location is used for error reports. *)
632
let type_node env nd loc =
633
  let is_main = nd.node_id = !Options.main_node in
634
  let vd_env_ol = nd.node_outputs@nd.node_locals in
635
  let vd_env =  nd.node_inputs@vd_env_ol in
636
  check_vd_env vd_env;
637
  let init_env = env in
638
  let delta_env = type_var_decl_list vd_env init_env nd.node_inputs in
639
  let delta_env = type_var_decl_list vd_env delta_env nd.node_outputs in
640
  let delta_env = type_var_decl_list vd_env delta_env nd.node_locals in
641
  let new_env = Env.overwrite env delta_env in
642
  let undefined_vars_init =
643
    List.fold_left
644
      (fun uvs v -> ISet.add v.var_id uvs)
645
      ISet.empty vd_env_ol in
646
  let undefined_vars =
647
    List.fold_left (type_eq (new_env, vd_env) is_main) undefined_vars_init (get_node_eqs nd)
648
  in
649
  (* Typing asserts *)
650
  List.iter (fun assert_ ->
651
    let assert_expr =  assert_.assert_expr in
652
    type_subtyping_arg (new_env, vd_env) is_main false assert_expr Type_predef.type_bool
653
  )  nd.node_asserts;
654

    
655
  (* Typing node annotations *)
656
  List.iter (fun expr_annot ->
657
    type_expr_annot (new_env, vd_env) is_main false expr_annot
658
  )  nd.node_annot;
659
  
660
  (* check that table is empty *)
661
  let local_consts = List.fold_left (fun res vdecl -> if vdecl.var_dec_const then ISet.add vdecl.var_id res else res) ISet.empty nd.node_locals in
662
  let undefined_vars = ISet.diff undefined_vars local_consts in
663
  if (not (ISet.is_empty undefined_vars)) then
664
    raise (Error (loc, Undefined_var undefined_vars));
665
  let ty_ins = type_of_vlist nd.node_inputs in
666
  let ty_outs = type_of_vlist nd.node_outputs in
667
  let ty_node = new_ty (Tarrow (ty_ins,ty_outs)) in
668
  generalize ty_node;
669
  (* TODO ? Check that no node in the hierarchy remains polymorphic ? *)
670
  nd.node_type <- ty_node;
671
  Env.add_value env nd.node_id ty_node
672

    
673
let type_imported_node env nd loc =
674
  let new_env = type_var_decl_list nd.nodei_inputs env nd.nodei_inputs in
675
  let vd_env = nd.nodei_inputs@nd.nodei_outputs in
676
  check_vd_env vd_env;
677
  ignore(type_var_decl_list vd_env new_env nd.nodei_outputs);
678
  let ty_ins = type_of_vlist nd.nodei_inputs in
679
  let ty_outs = type_of_vlist nd.nodei_outputs in
680
  let ty_node = new_ty (Tarrow (ty_ins,ty_outs)) in
681
  generalize ty_node;
682
(*
683
  if (is_polymorphic ty_node) then
684
    raise (Error (loc, Poly_imported_node nd.nodei_id));
685
*)
686
  let new_env = Env.add_value env nd.nodei_id ty_node in
687
  nd.nodei_type <- ty_node;
688
  new_env
689

    
690
let type_top_const env cdecl =
691
  let ty = type_const cdecl.const_loc cdecl.const_value in
692
  let d =
693
    if is_dimension_type ty
694
    then dimension_of_const cdecl.const_loc cdecl.const_value
695
    else Dimension.mkdim_var () in
696
  let ty = Type_predef.type_static d ty in
697
  let new_env = Env.add_value env cdecl.const_id ty in
698
  cdecl.const_type <- ty;
699
  new_env
700

    
701
let type_top_consts env clist =
702
  List.fold_left type_top_const env clist
703

    
704
let rec type_top_decl env decl =
705
  match decl.top_decl_desc with
706
  | Node nd -> (
707
      try
708
	type_node env nd decl.top_decl_loc
709
      with Error (loc, err) as exc -> (
710
	(*if !Options.global_inline then
711
	  Format.eprintf "Type error: failing node@.%a@.@?"
712
	    Printers.pp_node nd
713
	;*)
714
	raise exc)
715
  )
716
  | ImportedNode nd ->
717
      type_imported_node env nd decl.top_decl_loc
718
  | Const c ->
719
      type_top_const env c
720
  | TypeDef _ -> List.fold_left type_top_decl env (consts_of_enum_type decl)
721
  | Open _  -> env
722

    
723
let type_prog env decls =
724
try
725
  List.fold_left type_top_decl env decls
726
with Failure _ as exc -> raise exc
727

    
728
(* Once the Lustre program is fully typed,
729
   we must get back to the original description of dimensions,
730
   with constant parameters, instead of unifiable internal variables. *)
731

    
732
(* The following functions aims at 'unevaluating' dimension expressions occuring in array types,
733
   i.e. replacing unifiable second_order variables with the original static parameters.
734
   Once restored in this formulation, dimensions may be meaningfully printed.
735
*)
736
let uneval_vdecl_generics vdecl =
737
 if vdecl.var_dec_const
738
 then
739
   match get_static_value vdecl.var_type with
740
   | None   -> (Format.eprintf "internal error: %a@." Types.print_ty vdecl.var_type; assert false)
741
   | Some d -> Dimension.uneval vdecl.var_id d
742

    
743
let uneval_node_generics vdecls =
744
  List.iter uneval_vdecl_generics vdecls
745

    
746
let uneval_top_generics decl =
747
  match decl.top_decl_desc with
748
  | Node nd ->
749
      uneval_node_generics (nd.node_inputs @ nd.node_outputs)
750
  | ImportedNode nd ->
751
      uneval_node_generics (nd.nodei_inputs @ nd.nodei_outputs)
752
  | Const _
753
  | TypeDef _
754
  | Open _  -> ()
755

    
756
let uneval_prog_generics prog =
757
 List.iter uneval_top_generics prog
758

    
759
let rec get_imported_symbol decls id =
760
  match decls with
761
  | [] -> assert false
762
  | decl::q ->
763
     (match decl.top_decl_desc with
764
      | ImportedNode nd when id = nd.nodei_id && decl.top_decl_itf -> decl
765
      | Const c when id = c.const_id && decl.top_decl_itf -> decl
766
      | TypeDef _ -> get_imported_symbol (consts_of_enum_type decl @ q) id
767
      | _ -> get_imported_symbol q id)
768

    
769
let check_env_compat header declared computed = 
770
  uneval_prog_generics header;
771
  Env.iter declared (fun k decl_type_k ->
772
    let loc = (get_imported_symbol header k).top_decl_loc in 
773
    let computed_t =
774
      instantiate (ref []) (ref []) 
775
	(try Env.lookup_value computed k
776
	 with Not_found -> raise (Error (loc, Declared_but_undefined k))) in
777
    (*Types.print_ty Format.std_formatter decl_type_k;
778
      Types.print_ty Format.std_formatter computed_t;*)
779
    try_unify ~sub:true ~semi:true decl_type_k computed_t loc
780
  )
781

    
782
let check_typedef_top decl =
783
(*Format.eprintf "check_typedef %a@." Printers.pp_short_decl decl;*)
784
(*Format.eprintf "%a" Printers.pp_typedef (typedef_of_top decl);*)
785
(*Format.eprintf "%a" Corelang.print_type_table ();*)
786
  match decl.top_decl_desc with
787
  | TypeDef ty ->
788
     let owner = decl.top_decl_owner in
789
     let itf = decl.top_decl_itf in
790
     let decl' =
791
       try Hashtbl.find type_table (Tydec_const (typedef_of_top decl).tydef_id)
792
       with Not_found -> raise (Error (decl.top_decl_loc, Declared_but_undefined ("type "^ ty.tydef_id))) in
793
     let owner' = decl'.top_decl_owner in
794
(*Format.eprintf "def owner = %s@.decl owner = %s@." owner' owner;*)
795
     let itf' = decl'.top_decl_itf in
796
     (match decl'.top_decl_desc with
797
     | Const _ | Node _ | ImportedNode _ -> assert false
798
     | TypeDef ty' when coretype_equal ty'.tydef_desc ty.tydef_desc && owner' = owner && itf && (not itf') -> ()
799
     | _ -> raise (Error (decl.top_decl_loc, Type_mismatch ty.tydef_id)))
800
  | _  -> ()
801

    
802
let check_typedef_compat header =
803
  List.iter check_typedef_top header
804

    
805
(* Local Variables: *)
806
(* compile-command:"make -C .." *)
807
(* End: *)