Project

General

Profile

Statistics
| Branch: | Tag: | Revision:

lustrec / src / printers.ml @ 0d54d8a8

History | View | Annotate | Download (15.9 KB)

1
(********************************************************************)
2
(*                                                                  *)
3
(*  The LustreC compiler toolset   /  The LustreC Development Team  *)
4
(*  Copyright 2012 -    --   ONERA - CNRS - INPT                    *)
5
(*                                                                  *)
6
(*  LustreC is free software, distributed WITHOUT ANY WARRANTY      *)
7
(*  under the terms of the GNU Lesser General Public License        *)
8
(*  version 2.1.                                                    *)
9
(*                                                                  *)
10
(********************************************************************)
11

    
12
open Lustre_types
13
open Format
14
open Utils
15

    
16
(* Prints [v] as [pp_fun] would do, but adds a backslash at each end of line,
17
   following the C convention for multiple lines macro *)
18
let pp_as_c_macro pp_fun fmt v =
19
  let formatter_out_funs = pp_get_formatter_out_functions fmt () in
20
  let macro_newline () =
21
    begin
22
      formatter_out_funs.out_string "\\" 0 1;
23
      formatter_out_funs.out_newline ()
24
    end in
25
  begin
26
    pp_set_formatter_out_functions fmt { formatter_out_funs with out_newline = macro_newline };
27
    pp_fun fmt v;
28
    pp_set_formatter_out_functions fmt formatter_out_funs;
29
  end
30

    
31
let rec pp_var_struct_type_field fmt (label, tdesc) =
32
  fprintf fmt "%a : %a;" pp_print_string label pp_var_type_dec_desc tdesc
33
and pp_var_type_dec_desc fmt tdesc =
34
  match tdesc with 
35
  | Tydec_any -> fprintf fmt "<any>"
36
  | Tydec_int -> fprintf fmt "int"
37
  | Tydec_real -> fprintf fmt "real"
38
  (* | Tydec_float -> fprintf fmt "float" *)
39
  | Tydec_bool -> fprintf fmt "bool"
40
  | Tydec_clock t -> fprintf fmt "%a clock" pp_var_type_dec_desc t
41
  | Tydec_const t -> fprintf fmt "%s" t
42
  | Tydec_enum id_list -> fprintf fmt "enum {%a }" (fprintf_list ~sep:", " pp_print_string) id_list
43
  | Tydec_struct f_list -> fprintf fmt "struct {%a }" (fprintf_list ~sep:" " pp_var_struct_type_field) f_list
44
  | Tydec_array (s, t) -> fprintf fmt "%a^%a" pp_var_type_dec_desc t Dimension.pp_dimension s
45

    
46
let pp_var_type_dec fmt ty =
47
  pp_var_type_dec_desc fmt ty.ty_dec_desc
48

    
49
let pp_var_name fmt id = fprintf fmt "%s" id.var_id
50
let pp_var_type fmt id =
51
  if !Options.print_dec_types then
52
    pp_var_type_dec fmt id.var_dec_type
53
  else
54
    Types.print_node_ty fmt id.var_type
55
let pp_var_clock fmt id = Clocks.print_ck_suffix fmt id.var_clock
56
  
57
let pp_eq_lhs = fprintf_list ~sep:", " pp_print_string
58

    
59
let pp_var fmt id =
60
  fprintf fmt "%s%s: %a"
61
    (if id.var_dec_const then "const " else "")
62
    id.var_id
63
    pp_var_type id
64

    
65
let pp_quantifiers fmt (q, vars) =
66
  match q with
67
    | Forall -> fprintf fmt "forall %a" (fprintf_list ~sep:"; " pp_var) vars 
68
    | Exists -> fprintf fmt "exists %a" (fprintf_list ~sep:"; " pp_var) vars 
69

    
70
let rec pp_struct_const_field fmt (label, c) =
71
  fprintf fmt "%a = %a;" pp_print_string label pp_const c
72
and pp_const fmt c = 
73
  match c with
74
    | Const_int i -> pp_print_int fmt i
75
    | Const_real (c, e, s) -> pp_print_string fmt s (*if e = 0 then pp_print_int fmt c else if e < 0 then Format.fprintf fmt "%ie%i" c (-e) else Format.fprintf fmt "%ie-%i" c e *)
76
    (* | Const_float r -> pp_print_float fmt r *)
77
    | Const_tag  t -> pp_print_string fmt t
78
    | Const_array ca -> fprintf fmt "[%a]" (Utils.fprintf_list ~sep:"," pp_const) ca
79
    | Const_struct fl -> fprintf fmt "{%a }" (Utils.fprintf_list ~sep:" " pp_struct_const_field) fl
80

    
81
    (* used only for annotations *)
82
    | Const_string s -> pp_print_string fmt ("\"" ^ s ^ "\"")
83
    | Const_modeid s -> pp_print_string fmt ("\"" ^ s ^ "\"")
84

    
85

    
86
let pp_annot_key fmt kwds =
87
  match kwds with
88
  | [] -> assert false
89
  | [x] -> pp_print_string fmt x
90
  | _ -> fprintf fmt "/%a/" (fprintf_list ~sep:"/" pp_print_string) kwds
91

    
92
let rec pp_expr fmt expr =
93
  (match expr.expr_annot with 
94
  | None -> fprintf fmt "%t" 
95
  | Some ann -> fprintf fmt "@[(%a %t)@]" pp_expr_annot ann)
96
    (fun fmt -> 
97
      match expr.expr_desc with
98
    | Expr_const c -> pp_const fmt c
99
    | Expr_ident id -> fprintf fmt "%s" id
100
    | Expr_array a -> fprintf fmt "[%a]" pp_tuple a
101
    | Expr_access (a, d) -> fprintf fmt "%a[%a]" pp_expr a Dimension.pp_dimension d
102
    | Expr_power (a, d) -> fprintf fmt "(%a^%a)" pp_expr a Dimension.pp_dimension d
103
    | Expr_tuple el -> fprintf fmt "(%a)" pp_tuple el
104
    | Expr_ite (c, t, e) -> fprintf fmt "@[<hov 1>(if %a then@ @[<hov 2>%a@]@ else@ @[<hov 2>%a@]@])" pp_expr c pp_expr t pp_expr e
105
    | Expr_arrow (e1, e2) -> fprintf fmt "(%a -> %a)" pp_expr e1 pp_expr e2
106
    | Expr_fby (e1, e2) -> fprintf fmt "%a fby %a" pp_expr e1 pp_expr e2
107
    | Expr_pre e -> fprintf fmt "pre %a" pp_expr e
108
    | Expr_when (e, id, l) -> fprintf fmt "%a when %s(%s)" pp_expr e l id
109
    | Expr_merge (id, hl) -> 
110
      fprintf fmt "merge %s %a" id pp_handlers hl
111
    | Expr_appl (id, e, r) -> pp_app fmt id e r
112
    )
113
and pp_tuple fmt el =
114
 fprintf_list ~sep:"," pp_expr fmt el
115

    
116
and pp_handler fmt (t, h) =
117
 fprintf fmt "(%s -> %a)" t pp_expr h
118

    
119
and pp_handlers fmt hl =
120
 fprintf_list ~sep:" " pp_handler fmt hl
121

    
122
and pp_app fmt id e r =
123
  match r with
124
  | None -> pp_call fmt id e
125
  | Some c -> fprintf fmt "%t every (%a)" (fun fmt -> pp_call fmt id e) pp_expr c 
126

    
127
and pp_call fmt id e =
128
  match id, e.expr_desc with
129
  | "+", Expr_tuple([e1;e2]) -> fprintf fmt "(%a + %a)" pp_expr e1 pp_expr e2
130
  | "uminus", _ -> fprintf fmt "(- %a)" pp_expr e
131
  | "-", Expr_tuple([e1;e2]) -> fprintf fmt "(%a - %a)" pp_expr e1 pp_expr e2
132
  | "*", Expr_tuple([e1;e2]) -> fprintf fmt "(%a * %a)" pp_expr e1 pp_expr e2
133
  | "/", Expr_tuple([e1;e2]) -> fprintf fmt "(%a / %a)" pp_expr e1 pp_expr e2
134
  | "mod", Expr_tuple([e1;e2]) -> fprintf fmt "(%a mod %a)" pp_expr e1 pp_expr e2
135
  | "&&", Expr_tuple([e1;e2]) -> fprintf fmt "(%a and %a)" pp_expr e1 pp_expr e2
136
  | "||", Expr_tuple([e1;e2]) -> fprintf fmt "(%a or %a)" pp_expr e1 pp_expr e2
137
  | "xor", Expr_tuple([e1;e2]) -> fprintf fmt "(%a xor %a)" pp_expr e1 pp_expr e2
138
  | "impl", Expr_tuple([e1;e2]) -> fprintf fmt "(%a => %a)" pp_expr e1 pp_expr e2
139
  | "<", Expr_tuple([e1;e2]) -> fprintf fmt "(%a < %a)" pp_expr e1 pp_expr e2
140
  | "<=", Expr_tuple([e1;e2]) -> fprintf fmt "(%a <= %a)" pp_expr e1 pp_expr e2
141
  | ">", Expr_tuple([e1;e2]) -> fprintf fmt "(%a > %a)" pp_expr e1 pp_expr e2
142
  | ">=", Expr_tuple([e1;e2]) -> fprintf fmt "(%a >= %a)" pp_expr e1 pp_expr e2
143
  | "!=", Expr_tuple([e1;e2]) -> fprintf fmt "(%a <> %a)" pp_expr e1 pp_expr e2
144
  | "=", Expr_tuple([e1;e2]) -> fprintf fmt "(%a = %a)" pp_expr e1 pp_expr e2
145
  | "not", _ -> fprintf fmt "(not %a)" pp_expr e
146
  | _, Expr_tuple _ -> fprintf fmt "%s %a" id pp_expr e
147
  | _ -> fprintf fmt "%s (%a)" id pp_expr e
148

    
149
and pp_eexpr fmt e =
150
  fprintf fmt "%a%t %a"
151
    (Utils.fprintf_list ~sep:"; " pp_quantifiers) e.eexpr_quantifiers
152
    (fun fmt -> match e.eexpr_quantifiers with [] -> () | _ -> fprintf fmt ";")
153
    pp_expr e.eexpr_qfexpr
154

    
155
and  pp_sf_value fmt e =
156
   fprintf fmt "%a"
157
     (* (Utils.fprintf_list ~sep:"; " pp_quantifiers) e.eexpr_quantifiers *)
158
     (* (fun fmt -> match e.eexpr_quantifiers *)
159
     (*             with [] -> () *)
160
     (*                | _ -> fprintf fmt ";") *)
161
     pp_expr e.eexpr_qfexpr
162

    
163
and pp_s_function fmt expr_ann =
164
  let pp_annot fmt (kwds, ee) =
165
    fprintf fmt " %t : %a"
166
                   (fun fmt -> match kwds with
167
                               | [] -> assert false
168
                               | [x] -> pp_print_string fmt x
169
                               | _ -> fprintf fmt "%a" (fprintf_list ~sep:"/" pp_print_string) kwds)
170
                   pp_sf_value ee
171
  in
172
  fprintf_list ~sep:"@ " pp_annot fmt expr_ann.annots
173

    
174
and pp_expr_annot fmt expr_ann =
175
  let pp_annot fmt (kwds, ee) =
176
    fprintf fmt "(*! %a: %a; *)"
177
      pp_annot_key kwds
178
      pp_eexpr ee
179
  in
180
  fprintf_list ~sep:"@ " pp_annot fmt expr_ann.annots
181

    
182

    
183
let pp_asserts fmt asserts =
184
  match asserts with 
185
  | _::_ -> (
186
    fprintf fmt "(* Asserts definitions *)@ ";
187
    fprintf_list ~sep:"@ " (fun fmt assert_ -> 
188
      let expr = assert_.assert_expr in
189
      fprintf fmt "assert %a;" pp_expr expr 
190
    ) fmt asserts 
191
  )
192
  | _ -> ()
193

    
194
(*
195
let pp_node_var fmt id = fprintf fmt "%s%s: %a(%a)%a" (if id.var_dec_const then "const " else "") id.var_id print_dec_ty id.var_dec_type.ty_dec_desc Types.print_ty id.var_type Clocks.print_ck_suffix id.var_clock
196
*)
197
let pp_node_var fmt id =
198
  begin
199
    fprintf fmt "%s%s: %a%a"
200
      (if id.var_dec_const then "const " else "")
201
      id.var_id
202
      pp_var_type id
203
      pp_var_clock id;
204
    match id.var_dec_value with
205
    | None -> () 
206
    | Some v -> fprintf fmt " = %a" pp_expr v
207
  end 
208

    
209
let pp_node_args = fprintf_list ~sep:";@ " pp_node_var 
210

    
211
let pp_node_eq fmt eq = 
212
  fprintf fmt "%a = %a;" 
213
    pp_eq_lhs eq.eq_lhs
214
    pp_expr eq.eq_rhs
215

    
216
let pp_restart fmt restart =
217
  fprintf fmt "%s" (if restart then "restart" else "resume")
218

    
219
let pp_unless fmt (_, expr, restart, st) =
220
  fprintf fmt "unless %a %a %s"
221
    pp_expr expr
222
    pp_restart restart
223
    st
224

    
225
let pp_until fmt (_, expr, restart, st) =
226
  fprintf fmt "until %a %a %s"
227
    pp_expr expr
228
    pp_restart restart
229
    st
230

    
231
let rec pp_handler fmt handler =
232
  fprintf fmt "state %s:@ @[<v 2>  %a%t%alet@,@[<v 2>  %a@ %a@ %a@]@,tel@ %a@]"
233
    handler.hand_state
234
    (Utils.fprintf_list ~sep:"@ " pp_unless) handler.hand_unless
235
    (fun fmt -> if not ([] = handler.hand_unless) then fprintf fmt "@ ")
236
    (fun fmt locals ->
237
      match locals with [] -> () | _ ->
238
	fprintf fmt "@[<v 4>var %a@]@ " 
239
	  (Utils.fprintf_list ~sep:"@ " 
240
	     (fun fmt v -> fprintf fmt "%a;" pp_node_var v))
241
	  locals)
242
    handler.hand_locals
243
    (fprintf_list ~sep:"@ " pp_expr_annot) handler.hand_annots
244
    pp_node_stmts handler.hand_stmts
245
    pp_asserts handler.hand_asserts
246
    (Utils.fprintf_list ~sep:"@," pp_until) handler.hand_until
247

    
248
and pp_node_stmt fmt stmt =
249
  match stmt with
250
  | Eq eq -> pp_node_eq fmt eq
251
  | Aut aut -> pp_node_aut fmt aut
252

    
253
and pp_node_stmts fmt stmts = fprintf_list ~sep:"@ " pp_node_stmt fmt stmts
254

    
255
and pp_node_aut fmt aut =
256
  fprintf fmt "@[<v 0>automaton %s@,%a@]"
257
    aut.aut_id
258
    (Utils.fprintf_list ~sep:"@ " pp_handler) aut.aut_handlers
259

    
260
and pp_node_eqs fmt eqs = fprintf_list ~sep:"@ " pp_node_eq fmt eqs
261

    
262
let pp_typedef fmt ty =
263
  fprintf fmt "type %s = %a;" ty.tydef_id pp_var_type_dec_desc ty.tydef_desc
264

    
265
let pp_typedec fmt ty =
266
  fprintf fmt "type %s;" ty.tydec_id
267

    
268
(* let rec pp_var_type fmt ty =  *)
269
(*   fprintf fmt "%a" (match ty.tdesc with  *)
270
(*     | Tvar | Tarrow | Tlink | Tunivar -> assert false *)
271
(*     | Tint -> pp_print_string fmt "int" *)
272
(*     | Treal -> pp_print_string fmt "real" *)
273
(*     | Tbool -> pp_print_string fmt "bool" *)
274
(*     | Trat -> pp_print_string fmt "rat" *)
275
(*     | Tclock -> pp_print_string fmt "clock"  *)
276
(*     | Ttuple tel -> fprintf_list ~sep:" * " pp_var_type fmt tel *)
277
(*   ) *)
278

    
279

    
280

    
281
let pp_quantifiers fmt (q, vars) =
282
  match q with
283
    | Forall -> fprintf fmt "forall %a" (fprintf_list ~sep:"; " pp_var) vars 
284
    | Exists -> fprintf fmt "exists %a" (fprintf_list ~sep:"; " pp_var) vars 
285

    
286
let pp_eexpr fmt e =
287
  fprintf fmt "%a%t %a"
288
    (Utils.fprintf_list ~sep:"; " pp_quantifiers) e.eexpr_quantifiers
289
    (fun fmt -> match e.eexpr_quantifiers with [] -> () | _ -> fprintf fmt ";")
290
    pp_expr e.eexpr_qfexpr
291

    
292
let pp_spec fmt spec =
293
  fprintf fmt "@[<hov 2>(*@@ ";
294
  (* const are prefixed with const in pp_var and with nothing for regular
295
     variables. We adapt the call to produce the appropriate output. *)
296
  fprintf_list ~sep:"@,@@ " (fun fmt v ->
297
    fprintf fmt "%s%a = %t;"
298
      (if v.var_dec_const then "" else "var")
299
      pp_var v
300
      (fun fmt -> match v.var_dec_value with None -> () | Some e -> pp_expr fmt e)
301
  ) fmt (spec.consts @ spec.locals);
302
  fprintf_list ~sep:"@,@@ " (fun fmt r -> fprintf fmt "assume %a;" pp_eexpr r) fmt spec.assume;
303
  fprintf_list ~sep:"@,@@ " (fun fmt r -> fprintf fmt "guarantees %a;" pp_eexpr r) fmt spec.guarantees;
304
  fprintf_list ~sep:"@,@@ " (fun fmt mode ->
305
    fprintf fmt "mode %s (@[@ %a@ %a@]);" 
306
      mode.mode_id
307
      (fprintf_list ~sep:"@ " (fun fmt r -> fprintf fmt "require %a;" pp_eexpr r)) mode.require
308
      (fprintf_list ~sep:"@ " (fun fmt r -> fprintf fmt "ensure %a;" pp_eexpr r)) mode.ensure
309
  ) fmt spec.modes;
310
  fprintf_list ~sep:"@,@@ " (fun fmt import ->
311
    fprintf fmt "import %s (%a) returns (%a);" 
312
      import.import_nodeid
313
      (fprintf_list ~sep:"@ " pp_expr) import.inputs
314
      (fprintf_list ~sep:"@ " pp_expr) import.outputs
315
  ) fmt spec.imports;
316
  fprintf fmt "@]*)";
317
  ()
318

    
319
    
320
let pp_node fmt nd = 
321
fprintf fmt "@[<v 0>%a%t%s @[<hov 0>%s (@[%a)@]@ returns (@[%a)@]@]@ %a%alet@[<h 2>   @ @[<v>%a@ %a@ %a@]@]@ tel@]@ "
322
  (fun fmt s -> match s with Some s -> pp_spec fmt s | _ -> ()) nd.node_spec
323
  (fun fmt -> match nd.node_spec with None -> () | Some _ -> fprintf fmt "@ ")
324
  (if nd.node_dec_stateless then "function" else "node")
325
  nd.node_id
326
  pp_node_args nd.node_inputs
327
  pp_node_args nd.node_outputs
328
  (fun fmt locals ->
329
  match locals with [] -> () | _ ->
330
    fprintf fmt "@[<v 4>var %a@]@ " 
331
      (fprintf_list ~sep:"@ " 
332
	 (fun fmt v -> fprintf fmt "%a;" pp_node_var v))
333
      locals
334
  ) nd.node_locals
335
  (fun fmt checks ->
336
  match checks with [] -> () | _ ->
337
    fprintf fmt "@[<v 4>check@ %a@]@ " 
338
      (fprintf_list ~sep:"@ " 
339
	 (fun fmt d -> fprintf fmt "%a" Dimension.pp_dimension d))
340
      checks
341
  ) nd.node_checks
342
  (fprintf_list ~sep:"@ " pp_expr_annot) nd.node_annot
343
  pp_node_stmts nd.node_stmts
344
  pp_asserts nd.node_asserts
345
(*fprintf fmt "@ /* Scheduling: %a */ @ " (fprintf_list ~sep:", " pp_print_string) (Scheduling.schedule_node nd)*)
346

    
347
let pp_imported_node fmt ind = 
348
  fprintf fmt "@[<v>%s %s (%a) returns (%a)@]"
349
    (if ind.nodei_stateless then "function" else "node")
350
    ind.nodei_id
351
    pp_node_args ind.nodei_inputs
352
    pp_node_args ind.nodei_outputs
353

    
354
let pp_const_decl fmt cdecl =
355
  fprintf fmt "%s = %a;" cdecl.const_id pp_const cdecl.const_value
356

    
357
let pp_const_decl_list fmt clist = 
358
  fprintf_list ~sep:"@ " pp_const_decl fmt clist
359

    
360

    
361
  
362
let pp_decl fmt decl =
363
  match decl.top_decl_desc with
364
  | Node nd -> fprintf fmt "%a" pp_node nd
365
  | ImportedNode ind ->
366
     fprintf fmt "imported %a;" pp_imported_node ind
367
  | Const c -> fprintf fmt "const %a" pp_const_decl c
368
  | Open (local, s) -> if local then fprintf fmt "#open \"%s\"" s else fprintf fmt "#open <%s>" s
369
  | TypeDef tdef -> fprintf fmt "%a" pp_typedef tdef
370
  
371
let pp_prog fmt prog =
372
  (* we first print types: the function SortProg.sort could do the job but ut
373
     introduces a cyclic dependance *)
374
  let type_decl, others =
375
    List.partition (fun decl -> match decl.top_decl_desc with TypeDef _ -> true | _ -> false) prog
376
  in
377
  fprintf fmt "@[<v 0>%a@]" (fprintf_list ~sep:"@ " pp_decl) (type_decl@others)
378

    
379
(* Gives a short overview of model content. Do not print all node content *)
380
let pp_short_decl fmt decl =
381
  match decl.top_decl_desc with
382
  | Node nd -> fprintf fmt "node %s@ " nd.node_id
383
  | ImportedNode ind -> fprintf fmt "imported node %s" ind.nodei_id
384
  | Const c -> fprintf fmt "const %a@ " pp_const_decl c
385
  | Open (local, s) -> if local then fprintf fmt "#open \"%s\"@ " s else fprintf fmt "#open <%s>@ " s
386
  | TypeDef tdef -> fprintf fmt "type %s;@ " tdef.tydef_id
387
  
388
let pp_lusi fmt decl = 
389
  match decl.top_decl_desc with
390
  | ImportedNode ind -> fprintf fmt "%a;@ " pp_imported_node ind
391
  | Const c -> fprintf fmt "const %a@ " pp_const_decl c
392
  | Open (local, s) -> if local then fprintf fmt "#open \"%s\"@ " s else fprintf fmt "#open <%s>@ " s
393
  | TypeDef tdef -> fprintf fmt "%a@ " pp_typedef tdef
394
  | Node _ -> assert false
395
                
396
let pp_lusi_header fmt basename prog =
397
  fprintf fmt "@[<v 0>";
398
  fprintf fmt "(* Generated Lustre Interface file from %s.lus *)@ " basename;
399
  fprintf fmt "(* by Lustre-C compiler version %s, %a *)@ " Version.number pp_date (Unix.gmtime (Unix.time ()));
400
  fprintf fmt "(* Feel free to mask some of the definitions by removing them from this file. *)@ @ ";
401
  List.iter (fprintf fmt "%a@ " pp_lusi) prog;
402
  fprintf fmt "@]@."
403

    
404
let pp_offset fmt offset =
405
  match offset with
406
  | Index i -> fprintf fmt "[%a]" Dimension.pp_dimension i
407
  | Field f -> fprintf fmt ".%s" f
408

    
409
(* Local Variables: *)
410
(* compile-command:"make -C .." *)
411
(* End: *)