CristalCaveGem » LustreC » Lustrec-Tests

# - Find Lustre compiler

# Find the Lustre synchronous language compiler with associated includes path.

# See https://cavale.enseeiht.fr/redmine/projects/lustrec

# This module defines

#  LUSTRE_COMPILER, the lustre compiler

#  LUSTRE_COMPILER_VERSION, the version of the lustre compiler

#  LUSTRE_INCLUDE_DIR, where to find dword.h, etc.

#  LUSTRE_FOUND, If false, Lustre was not found.

# On can set LUSTRE_PATH_HINT before using find_package(Lustre) and the

# module with use the PATH as a hint to find lustrec.

#

# The hint can be given on the command line too:

#   cmake -DLUSTRE_PATH_HINT=/DATA/ERIC/Lustre/lustre-x.y /path/to/source

#

# The module defines some functions:

#   Lustre_Compile([NODE <Lustre Main Node>]

#                  LUS_FILE <Lustre file>

#                  [USER_C_FILES <C files>]

#                  [VERBOSE <level>]

#		   [OPTIONS <options>]

#				[DIR <directory dest>])

#

# When used the Lustre_Compile macro define the variable

# LUSTRE_GENERATED_C_FILES_<libraryName> in the parent scope

# so that the caller can get (if needed) the list of Lustre generated files.

# The VERBOSE level is a numeric value passed directly to the -verbose

# command line option of the lustre compiler

#

include (./modules/helpful_functions.cmake)

if(LUSTRE_PATH_HINT)

  message(STATUS "FindLustre: using PATH HINT: ${LUSTRE_PATH_HINT}")

else()

  set(LUSTRE_PATH_HINT)

endif()

# FIND_PROGRAM twice using NO_DEFAULT_PATH on first shot

find_program(LUSTRE_COMPILER

  NAMES lustrec

  HINTS ${LUSTRE_PATH_HINT}

  PATH_SUFFIXES bin

  DOC "Path to the Lustre compiler command 'lustrec'")

find_program(LUSTRE_COMPILER

  NAMES lustrec

  PATHS ${LUSTRE_PATH_HINT}

  PATH_SUFFIXES bin

  NO_DEFAULT_PATH

  DOC "Path to the Lustre compiler command 'lustrec'")

if(LUSTRE_COMPILER)

    # get the path where the lustre compiler was found

    get_filename_component(LUSTRE_PATH ${LUSTRE_COMPILER} PATH)

    # remove bin

    get_filename_component(LUSTRE_PATH ${LUSTRE_PATH} PATH)

    # add path to LUSTRE_PATH_HINT

    list(APPEND LUSTRE_PATH_HINT ${LUSTRE_PATH})

    execute_process(COMMAND ${LUSTRE_COMPILER} -version

        OUTPUT_VARIABLE LUSTRE_COMPILER_VERSION

        OUTPUT_STRIP_TRAILING_WHITESPACE)

    message(STATUS "Lustre compiler version is : ${LUSTRE_COMPILER_VERSION}")

endif(LUSTRE_COMPILER)

find_path(LUSTRE_INCLUDE_DIR

          NAMES arrow.h

          PATHS ${LUSTRE_PATH_HINT}

          PATH_SUFFIXES include/lustrec

          DOC "The Lustre include headers")

find_program(LUSTRE_T

  NAMES lustret

  HINTS ${LUSTRE_PATH_HINT}

  PATH_SUFFIXES bin

  DOC "Path to the Lustre compiler command 'lustret'")

find_program(LUSTRE_T

  NAMES lustret

  PATHS ${LUSTRE_PATH_HINT}

  PATH_SUFFIXES bin

  NO_DEFAULT_PATH

  DOC "Path to the Lustre compiler command 'lustret'")

# Macros used to compile a lustre library

include(CMakeParseArguments)

function(Lustre_Compile)

  set(options "")

  set(oneValueArgs  NODE VERBOSE LUS_FILE DIR DST_DIR)

  set(multiValueArgs  OPTS USER_C_FILES )

  cmake_parse_arguments(LUS "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  get_lustre_name_ext(${LUS_LUS_FILE} L E)

  # get_filename_component(L ${LUS_LUS_FILE} NAME_WE)

  # get_filename_component(E ${LUS_LUS_FILE} EXT)

  set(LUSTREC_ARGS "")

  if(LUS_DST_DIR)

    set(OUTPUT_PATH "${LUS_DST_DIR}")

  else()

    set(OUTPUT_PATH "${CMAKE_CURRENT_BINARY_DIR}")

  endif()

  if(LUS_NODE)

    set(LUSTRE_OUTPUT_DIR "${OUTPUT_PATH}/${L}/node_${LUS_NODE}")

    set(LUSTREC_ARGS ${LUSTREC_ARGS} -node ${LUS_NODE} )

  else()

    set(LUSTRE_OUTPUT_DIR "${OUTPUT_PATH}/${L}")

  endif()

  if(LUS_OPTS)

    CUT_OPTIONS("${LUS_OPTS}" LUS_OPTS_CUT)

    if(LUS_NODE)

	set(LUSTRE_OUTPUT_DIR "${LUSTRE_OUTPUT_DIR}_${LUS_OPTS_CUT}")

    else(LUS_NODE)

	set(LUSTRE_OUTPUT_DIR "${LUSTRE_OUTPUT_DIR}/${LUS_OPTS_CUT}")

    endif(LUS_NODE)

	set(LUSTREC_ARGS ${LUSTREC_ARGS} ${LUS_OPTS} )

  endif(LUS_OPTS)

  if (LUS_VERBOSE)

    set(LUSTRE_VERBOSE_OPT "-verbose ${LUS_VERBOSE}")

    set(LUSTREC_ARGS ${LUSTREC_ARGS} -verbose ${LUS_VERBOSE} )

  endif()

  set(LUSTRE_GENERATED_FILES "")

  file(MAKE_DIRECTORY ${LUSTRE_OUTPUT_DIR})

  # create list of generated C files in parent scope

  if ("${E}" STREQUAL ".lus")

	set(LUSTRE_GENERATED_FILES ${LUSTRE_OUTPUT_DIR}/${L}.h   ${LUSTRE_OUTPUT_DIR}/${L}.lusic )

	if (LUS_NODE)

		set(LUSTRE_GENERATED_FILES ${LUSTRE_GENERATED_FILES} ${LUSTRE_OUTPUT_DIR}/${L}.c ${LUSTRE_OUTPUT_DIR}/${L}_alloc.h ${LUSTRE_OUTPUT_DIR}/${L}_main.c ${LUSTRE_OUTPUT_DIR}/${L}.makefile)

	endif(LUS_NODE)

	if(LUS_OPTS MATCHES "horn")

		set(LUSTRE_GENERATED_FILES ${LUSTRE_GENERATED_FILES} ${LUSTRE_OUTPUT_DIR}/${L}.smt2)

	endif(LUS_OPTS MATCHES "horn")

  elseif("${E}" STREQUAL ".lusi")

	set(LUSTRE_GENERATED_FILES ${LUSTRE_OUTPUT_DIR}/${L}.h)

  endif()

  if(LUS_DIR)

	set(LUSTRE_OUTPUT_DIR ${LUS_DIR} )

  endif()

  set(LUSTREC_ARGS ${LUSTREC_ARGS} -d ${LUSTRE_OUTPUT_DIR} ${LUS_LUS_FILE})

  set(LUSTREC_ARGS_${L}_${LUS_NODE}_${LUS_OPTS_CUT} "${LUSTREC_ARGS}" PARENT_SCOPE)

  set(LUSTRE_GENERATED_FILES_${L}_${LUS_NODE}_${LUS_OPTS_CUT} "${LUSTRE_GENERATED_FILES}" PARENT_SCOPE)

  set(LUSTRE_OUTPUT_DIR_${L}_${LUS_NODE}_${LUS_OPTS_CUT} "${LUSTRE_OUTPUT_DIR}" PARENT_SCOPE)

endfunction(Lustre_Compile)

# handle the QUIETLY and REQUIRED arguments and set LUSTRE_FOUND to TRUE if

# all listed variables are TRUE

include(FindPackageHandleStandardArgs)

FIND_PACKAGE_HANDLE_STANDARD_ARGS(LUSTRE

                                  REQUIRED_VARS LUSTRE_COMPILER LUSTRE_INCLUDE_DIR)

# VERSION FPHSA options not handled by CMake version < 2.8.2)

#                                  VERSION_VAR LUSTRE_COMPILER_VERSION)

mark_as_advanced(LUSTRE_INCLUDE_DIR)