CristalCaveGem » LustreC » Lustrec-Tests

include(CMakeParseArguments)

include(FindUnixCommands)

#******************first stratefy :generate input values and their outputs for reference

function(Copy_or_generate_lusi_input_and_output_values_for_reference )

  set(options "")

  set(oneValueArgs  NODE LUS_FILE  SRC_DIR DST_DIR MAX)

  set(multiValueArgs  OPTS )

  cmake_parse_arguments(GEN "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  #message("check references files for ${GEN_LUS_FILE}  ")

  get_filename_component(L ${GEN_LUS_FILE} NAME_WE)

  set(LUSTRE_OUTPUT_DIR "${GEN_DST_DIR}/${L}")

  file(COPY ${GEN_LUS_FILE}   DESTINATION  ${LUSTRE_OUTPUT_DIR})

  #generate .lusi if not exists

  if(EXISTS ${GEN_SRC_DIR}/${L}.lusi)

    file(COPY  ${GEN_SRC_DIR}/${L}.lusi DESTINATION  ${LUSTRE_OUTPUT_DIR})

  else()

    message("generate ${L}.lusi \n")

    Lustre_Compile(LUS_FILE ${GEN_LUS_FILE}

      NODE ""

      OPTS "-lusi"

      DIR ${GEN_SRC_DIR}

      DST_DIR ${GEN_DST_DIR})

    CUT_OPTIONS("-lusi" GEN_OPTS_CUT_0)

    execute_process(RESULT_VARIABLE res 

     COMMAND ${LUSTRE_COMPILER} ${LUSTREC_ARGS_${L}__${GEN_OPTS_CUT_0}} 

     WORKING_DIRECTORY ${GEN_SRC_DIR})

    if(${res} STREQUAL "0")

      file(COPY  ${GEN_SRC_DIR}/${L}.lusi DESTINATION  ${LUSTRE_OUTPUT_DIR})

    else()

      message(FATAL_ERROR "${L}.lusi couldn't be generated")

    endif()

  endif()

  #generate input and output values

  if(EXISTS ${GEN_SRC_DIR}/${L}_${GEN_NODE}_input_values)

    file(COPY  ${GEN_SRC_DIR}/${L}_${GEN_NODE}_input_values DESTINATION  ${LUSTRE_OUTPUT_DIR})

  elseif(EXISTS ${GEN_SRC_DIR}/${L}.lusi)

    message("generate ${L}_${GEN_NODE}_input_values \n")

    execute_process(RESULT_VARIABLE res 

      COMMAND ${JAVA_RUNTIME} -cp ${CMAKE_BINARY_DIR}/modules/ Generate_inputs_lusi ${GEN_NODE} ${L}.lusi ${GEN_MAX}

      WORKING_DIRECTORY ${GEN_SRC_DIR})

    if(${res} STREQUAL "0")

      file(COPY  ${GEN_SRC_DIR}/${L}_${GEN_NODE}_input_values DESTINATION  ${LUSTRE_OUTPUT_DIR})

    else()

      message(FATAL_ERROR "${L}_input_values couldn't be generated")

    endif()

  endif()

  if(GEN_OPTS)

    CUT_OPTIONS("${GEN_OPTS}" GEN_OPTS_CUT)

  endif()

  if(EXISTS ${GEN_SRC_DIR}/${L}_${GEN_NODE}_${GEN_OPTS_CUT}_output_values)

    file(COPY  ${GEN_SRC_DIR}/${L}_${GEN_NODE}_${GEN_OPTS_CUT}_output_values DESTINATION  ${LUSTRE_OUTPUT_DIR})

  elseif(EXISTS ${GEN_SRC_DIR}/${L}_${GEN_NODE}_input_values)

    message("generate  ${L}_${GEN_NODE}_${GEN_OPTS_CUT}_output_values for reference \n")

    Lustre_Compile(LUS_FILE ${GEN_LUS_FILE}

      NODE ${GEN_NODE}

      OPTS ${GEN_OPTS}

      DIR ${GEN_SRC_DIR}

      DST_DIR ${GEN_DST_DIR})

    execute_process(

      COMMAND ${LUSTRE_COMPILER} ${LUSTREC_ARGS_${L}_${GEN_NODE}_${GEN_OPTS_CUT}} 

      WORKING_DIRECTORY ${GEN_SRC_DIR})			

    execute_process(

      COMMAND  make -f ${L}.makefile

      WORKING_DIRECTORY ${GEN_SRC_DIR})	

    execute_process(RESULT_VARIABLE res 

      COMMAND ${BASH} -c "./${L}_${GEN_NODE} < ${L}_${GEN_NODE}_input_values > ${L}_${GEN_NODE}_${GEN_OPTS_CUT}_output_values"

      WORKING_DIRECTORY ${GEN_SRC_DIR})	

    file(REMOVE ${GEN_SRC_DIR}/${L}_${GEN_NODE} ${GEN_SRC_DIR}/io_frontend.o ${GEN_SRC_DIR}/${L}.c ${GEN_SRC_DIR}/${L}.h ${GEN_SRC_DIR}/${L}.lusic ${GEN_SRC_DIR}/${L}.makefile ${GEN_SRC_DIR}/${L}.o ${GEN_SRC_DIR}/${L}_alloc.h ${GEN_SRC_DIR}/${L}_main.c ${GEN_SRC_DIR}/${L}_main.o )

    if(${res} STREQUAL "0")

      file(COPY  ${GEN_SRC_DIR}/${L}_${GEN_NODE}_${GEN_OPTS_CUT}_output_values DESTINATION  ${LUSTRE_OUTPUT_DIR})

    else()

      message(FATAL_ERROR "${L}_${GEN_NODE}_${GEN_OPTS_CUT}_output_values Error")

    endif()

  endif()

endfunction(Copy_or_generate_lusi_input_and_output_values_for_reference)

#****************************second stratefy :generate zustre output.xml for reference

function(Copy_or_generate_zustre_output_xml_for_reference )

  set(options "")

  set(oneValueArgs  NODE LUS_FILE SRC_DIR DST_DIR)

  set(multiValueArgs  OPTS )

  cmake_parse_arguments(GEN "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  if(GEN_OPTS)

    CUT_OPTIONS("${GEN_OPTS}" ZUS_OPTS_CUT)

  endif()

  get_filename_component(L ${GEN_LUS_FILE} NAME_WE)

  set(LUSTRE_OUTPUT_DIR "${GEN_DST_DIR}/${L}")

  if(EXISTS ${GEN_SRC_DIR}/${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml)

    file(COPY ${GEN_SRC_DIR}/${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml   DESTINATION  ${LUSTRE_OUTPUT_DIR})

    file(READ ${GEN_SRC_DIR}/${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml ${L}_${GEN_NODE}_zustre_output)		

  else()

    message("generate ${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml for reference\n")

    Zustre_Compile(LUS_FILE ${GEN_LUS_FILE}

      NODE ${GEN_NODE}

      OPTS ${GEN_OPTS}

      DST_DIR ${GEN_DST_DIR}

      )

    execute_process(RESULT_VARIABLE res 

      OUTPUT_VARIABLE ${L}_${GEN_NODE}_zustre_output

      COMMAND  ${ZUSTRE_COMPILER} ${ZUSTRE_ARGS_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}} 

      WORKING_DIRECTORY ${GEN_SRC_DIR})

    file(WRITE ${GEN_SRC_DIR}/${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml ${${L}_${GEN_NODE}_zustre_output})

    file(COPY ${GEN_SRC_DIR}/${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml   DESTINATION  ${LUSTRE_OUTPUT_DIR})

  endif()

  if( ${${L}_${GEN_NODE}_zustre_output} MATCHES "<Answer>CEX</Answer>")

    set(ZUSTRE_ANSWER "CEX")

  elseif( ${${L}_${GEN_NODE}_zustre_output} MATCHES "<Answer>SAFE</Answer>")

    set(ZUSTRE_ANSWER "SAFE")

  elseif( ${${L}_${GEN_NODE}_zustre_output} MATCHES "<Answer>TIMEOUT</Answer>")

    set(ZUSTRE_ANSWER "TIMEOUT")

  else()

    set(ZUSTRE_ANSWER "ERROR")

  endif()

  set(ZUSTRE_ANSWER_${L}_${GEN_NODE} "${ZUSTRE_ANSWER}" PARENT_SCOPE)

endfunction(Copy_or_generate_zustre_output_xml_for_reference )

#***********************third strategy: Compile with zustre and compare

function(Zustre_compile_and_compare_to_reference)

  set(options "")

  set(oneValueArgs  NODE LUS_FILE  TESTS_PREFIX CALL_ID SRC_DIR DST_DIR)

  set(multiValueArgs  OPTS )

  cmake_parse_arguments(GEN "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  get_filename_component(L ${GEN_LUS_FILE} NAME_WE)

  Lustre_Compile(LUS_FILE ${GEN_LUS_FILE}

    NODE ""

    OPTS "-horn"

    DST_DIR ${GEN_DST_DIR}

    )

  CUT_OPTIONS("-horn" LUS_OPTS_CUT)

  add_test(NAME ${GEN_TESTS_PREFIX}_COMPIL_LUSTRE_HORN_${L}__${LUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND  ${LUSTRE_COMPILER} ${LUSTREC_ARGS_${L}__${LUS_OPTS_CUT}} 

    )

  Zustre_Compile(LUS_FILE ${GEN_LUS_FILE}

    NODE ${GEN_NODE}

    OPTS ${GEN_OPTS}

    DST_DIR ${GEN_DST_DIR}

    )

  if(GEN_OPTS)

    CUT_OPTIONS("${GEN_OPTS}" ZUS_OPTS_CUT)

  endif()

  set(ZUSTRE_OUTPUT_DIR ${ZUSTRE_OUTPUT_DIR_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}})

  set(ZUSTRE_ARGS_TEMP "${ZUSTRE_ARGS_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}}" "> ${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml")

  JOIN("${ZUSTRE_ARGS_TEMP}" " " ZUSTRE_ARGS)

  add_test(NAME ${GEN_TESTS_PREFIX}_COMPIL_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND bash -c "${ZUSTRE_COMPILER} ${ZUSTRE_ARGS}"

    WORKING_DIRECTORY ${ZUSTRE_OUTPUT_DIR}

    )

  SET_TESTS_PROPERTIES (  ${GEN_TESTS_PREFIX}_COMPIL_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

    PROPERTIES FAIL_REGULAR_EXPRESSION "AssertionError;ERROR;Failed;Traceback"

    DEPENDS ${GEN_TESTS_PREFIX}_COMPIL_LUSTRE_HORN_${L}__${LUS_OPTS_CUT}_${GEN_CALL_ID})

  add_test(NAME ${GEN_TESTS_PREFIX}_COMPARE_REF_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND ${CMAKE_COMMAND} -DREF=${GEN_DST_DIR}/${L}/${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml

                             -DGEN=${ZUSTRE_OUTPUT_DIR}/${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml

    	    -P ${CMAKE_SOURCE_DIR}/modules/compare_ref_zustre.cmake

    WORKING_DIRECTORY ${ZUSTRE_OUTPUT_DIR}

    )

  SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_COMPARE_REF_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

    PROPERTIES REQUIRED_FILES  "${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml"

    DEPENDS ${GEN_TESTS_PREFIX}_COMPIL_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID})

  # add_test(NAME ${GEN_TESTS_PREFIX}_TAILGEN_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

  #   COMMAND bash -c "tail -n +8 ${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml > ${L}_tailed1.xml; | grep Answer | awk '{$1=$1};1'"

  #   WORKING_DIRECTORY ${ZUSTRE_OUTPUT_DIR}

  #   )

  # SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_TAILGEN_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

  #   PROPERTIES REQUIRED_FILES  ${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml

  #   DEPENDS ${GEN_TESTS_PREFIX}_COMPIL_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID})

  # add_test(NAME ${GEN_TESTS_PREFIX}_TAILREF_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

  #   COMMAND bash -c "tail -n +8 ${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml > ${L}_${GEN_NODE}_tailed2.xml"

  #   WORKING_DIRECTORY ${GEN_DST_DIR}/${L}/

  #   )

  # SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_TAILREF_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

  #   PROPERTIES REQUIRED_FILES  ${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml

  #   DEPENDS ${GEN_TESTS_PREFIX}_TAILGEN_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID})

  # add_test(NAME ${GEN_TESTS_PREFIX}_DIFF_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

  #   COMMAND ${CMAKE_COMMAND} -E compare_files  ${L}_tailed1.xml  ../${L}_${GEN_NODE}_tailed2.xml

  #   WORKING_DIRECTORY ${ZUSTRE_OUTPUT_DIR}

  #   )

  # SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_DIFF_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

  #   PROPERTIES REQUIRED_FILES  ${L}_tailed1.xml

  #   DEPENDS ${GEN_TESTS_PREFIX}_TAILREF_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID})	

endfunction(Zustre_compile_and_compare_to_reference)

#***********************fourth strategy: compare in case of CEX examples the Zustre trace with lustrec

function(Compare_Zustre_and_Lustrec_outputs)

  set(options "")

  set(oneValueArgs  NODE LUS_FILE  CALL_ID TESTS_PREFIX SRC_DIR DST_DIR)

  set(multiValueArgs  OPTS )

  cmake_parse_arguments(GEN "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  get_filename_component(L ${GEN_LUS_FILE} NAME_WE)

  Zustre_Compile(LUS_FILE ${GEN_LUS_FILE}

    NODE ${GEN_NODE}

    OPTS ${GEN_OPTS}

    DST_DIR ${GEN_DST_DIR}

    )

  if(GEN_OPTS)

    CUT_OPTIONS("${GEN_OPTS}" ZUS_OPTS_CUT)

  endif()

  set(ZUSTRE_OUTPUT_DIR ${ZUSTRE_OUTPUT_DIR_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}})

  add_test(NAME ${GEN_TESTS_PREFIX}_XPathParser_lusi_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND ${JAVA_RUNTIME} -cp ${CMAKE_BINARY_DIR}/modules/ XPathParser_lusi ${GEN_NODE} ../${L}.lusi ${L}_${GEN_NODE}_${ZUS_OPTS_CUT}.xml

    WORKING_DIRECTORY ${ZUSTRE_OUTPUT_DIR}

    )

  SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_XPathParser_lusi_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID}

    PROPERTIES REQUIRED_FILES  ${GEN_DST_DIR}/${L}/${L}.lusi 

    DEPENDS ${GEN_TESTS_PREFIX}_COMPIL_ZUSTRE_${L}_${GEN_NODE}_${ZUS_OPTS_CUT}_${GEN_CALL_ID} )	

  Lustre_Compile(LUS_FILE ${lus_file}

    NODE ${GEN_NODE}

    OPTS ""

    DIR ${ZUSTRE_OUTPUT_DIR}

    DST_DIR ${GEN_DST_DIR})

  set(LUS_OPTS_CUT "")

  add_test(NAME ${GEN_TESTS_PREFIX}_COMPIL_LUSTRE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND  ${LUSTRE_COMPILER} ${LUSTREC_ARGS_${L}_${GEN_NODE}_${LUS_OPTS_CUT}} 

    WORKING_DIRECTORY ${ZUSTRE_OUTPUT_DIR}

    )

  add_test(NAME ${GEN_TESTS_PREFIX}_MAKE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND  make -f ${L}.makefile

    WORKING_DIRECTORY ${ZUSTRE_OUTPUT_DIR}

    )

  SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_MAKE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    PROPERTIES DEPENDS ${GEN_TESTS_PREFIX}_COMPIL_LUSTRE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    REQUIRED_FILES ${L}.makefile

    )

  if (BASH)

    add_test(

      NAME ${GEN_TESTS_PREFIX}_BIN_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID} 

      COMMAND ${BASH} -c "./${L}_${GEN_NODE} < input_values > ${L}_${GEN_NODE}_outputs"

      WORKING_DIRECTORY ${ZUSTRE_OUTPUT_DIR}

      )

    SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_BIN_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

      PROPERTIES REQUIRED_FILES ${L}_${GEN_NODE}

      DEPENDS ${GEN_TESTS_PREFIX}_MAKE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID})

  else()

    message(FATAL_ERROR "Unknown shell command for ${CMAKE_HOST_SYSTEM_NAME}")

  endif()

  #************** compare **********************************

  add_test(NAME ${GEN_TESTS_PREFIX}_COMPARE_OUTPUTS_OF_LUSTREC_ZUSTRE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND ${CMAKE_COMMAND} -E compare_files ${L}_${GEN_NODE}_outputs ZUSTRE_output_values

    WORKING_DIRECTORY ${ZUSTRE_OUTPUT_DIR}

    )

  SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_COMPARE_OUTPUTS_OF_LUSTREC_ZUSTRE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    PROPERTIES REQUIRED_FILES ${L}_${GEN_NODE}_outputs

    DEPENDS ${GEN_TESTS_PREFIX}_BIN_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID} )

endfunction()

#******************************fifth strategy, test the lustrec binary with outputs of reference

function(Lustre_compile_and_compare_to_reference)

  set(options "")

  set(oneValueArgs  NODE LUS_FILE CALL_ID  TESTS_PREFIX SRC_DIR DST_DIR)

  set(multiValueArgs  OPTS )

  cmake_parse_arguments(GEN "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})

  get_filename_component(L ${GEN_LUS_FILE} NAME_WE)

  # First command generate C files from Lustre file

  Lustre_Compile(LUS_FILE ${GEN_LUS_FILE}

    NODE ${GEN_NODE}

    OPTS ${GEN_OPTS}

    DST_DIR ${GEN_DST_DIR}

    )

  if(GEN_OPTS)

    CUT_OPTIONS("${GEN_OPTS}" LUS_OPTS_CUT)

  endif()

  add_test(NAME ${GEN_TESTS_PREFIX}_COMPIL_LUSTRE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND  ${LUSTRE_COMPILER} ${LUSTREC_ARGS_${L}_${GEN_NODE}_${LUS_OPTS_CUT}}

    WORKING_DIRECTORY ${LUSTRE_OUTPUT_DIR_${L}_${GEN_NODE}_${LUS_OPTS_CUT}}

    )

  #********************* make -f ${L}.makefile ***************************

  add_test(NAME ${GEN_TESTS_PREFIX}_MAKE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND  make -f ${L}.makefile

    WORKING_DIRECTORY ${LUSTRE_OUTPUT_DIR_${L}_${GEN_NODE}_${LUS_OPTS_CUT}}

    )

  SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_MAKE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    PROPERTIES DEPENDS ${GEN_TESTS_PREFIX}_COMPIL_LUSTRE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    REQUIRED_FILES ${L}.makefile

    )

  #************** execute C binary **********************************

  if (BASH)

    add_test(

      NAME ${GEN_TESTS_PREFIX}_BIN_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID} 

      COMMAND ${BASH} -c "./${L}_${GEN_NODE} < ../${L}_${GEN_NODE}_input_values > ${L}_${GEN_NODE}_${LUS_OPTS_CUT}_output_values"

      WORKING_DIRECTORY ${LUSTRE_OUTPUT_DIR_${L}_${GEN_NODE}_${LUS_OPTS_CUT}}

      )

    SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_BIN_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

      PROPERTIES REQUIRED_FILES ${L}_${GEN_NODE}

      DEPENDS ${GEN_TESTS_PREFIX}_MAKE_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID})

  else()

    message(FATAL_ERROR "Unknown shell command ${BASH} -c for ${CMAKE_HOST_SYSTEM_NAME}")

  endif()

  #************** execute C binary **********************************

  add_test(NAME ${GEN_TESTS_PREFIX}_DIFF_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    COMMAND ${CMAKE_COMMAND} -E compare_files  ${L}_${GEN_NODE}_${LUS_OPTS_CUT}_output_values ../${L}_${GEN_NODE}__output_values 

    WORKING_DIRECTORY ${LUSTRE_OUTPUT_DIR_${L}_${GEN_NODE}_${LUS_OPTS_CUT}}

    )

  SET_TESTS_PROPERTIES ( ${GEN_TESTS_PREFIX}_DIFF_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID}

    PROPERTIES REQUIRED_FILES  ${L}_${GEN_NODE}_${LUS_OPTS_CUT}_output_values

    DEPENDS ${GEN_TESTS_PREFIX}_BIN_${L}_${GEN_NODE}_${LUS_OPTS_CUT}_${GEN_CALL_ID} )

endfunction()